/* ZOOMIN (STD) -- Zoom In */
/* ZOOMIN (STD) -- Zoom groesser */
/* -- INTENDED FOR KEY-CALL USE -- */
/*
// Copyright (c) 1997-2012 Oliver Bartels F+E, Muenchen
// Author: Roman Ludwig
// Changes History:
//	rl (120427) RELEASED FOR BAE V7.8.
//	rl (101019) RELEASED FOR BAE V7.6.
//	rl (091021) RELEASED FOR BAE V7.4.
//	rl (081014) RELEASED FOR BAE V7.2.
//	rl (080605) ENHANCEMENT:
//		Added turbo zoom to background grid option.
//	rl (071029) RELEASED FOR BAE V7.0.
//	rl (060829) RELEASED FOR BAE V6.8.
//	rl (050906) RELEASED FOR BAE V6.6.
//	rl (040831) RELEASED FOR BAE V6.4.
//	rl (030904) RELEASED FOR BAE V6.2.
//	rl (030715) ENHANCEMENT:
//		Improved mouse positioning in side menu environment.
//	rl (021209) RELEASED FOR BAE V6.0.
//	rl (020802) CHANGE:
//		Changed zoom destination window to preserve mouse position
//		in element to allow subsequent zooms without mouse move.
//	rl (020618) RELEASED FOR BAE V5.4.
//	rl (011023) BUGFIX:
//		Enabled call in CAM-View environment.
//	rl (010625) RELEASED FOR BAE V5.0.
//	rl (000509) RELEASED FOR BAE V4.6.
//	rl (990625) RELEASED FOR BAE V4.4.
//	rl (990623) BUGFIX:
//		Zoom to windows center if mouse outside window
//	rl (980910) RELEASED FOR BAE V4.2.
//	mb (980420) CHANGE:
//		Clear dialog line at end.
//	rl (970929) RELEASED FOR BAE V4.0.
//	rl (970725) IMPROVEMENT:
//		Zoom to mouse position
//	rl (970604) ORIGINAL CODING.
//
// DESCRIPTION
//
// The zoomin User Language program performs a
// zoom in/zoom larger display command.
*/

// Includes
#include "std.ulh"			// User Language standard include

// Disable undo state request
#pragma ULCALLERNOUNDO

// INI file parameter name definitions
#define PAR_ZOOMCENTER	"ZOOMCENTER_STD"	// Zoom center mode

// Globals
#define MINGRIDSTEP	0.003		// Min. display grid step value
#define SMALLVAL	0.00000001	// Small compare value
static int PULLDOWN	= bae_swconfig(3)==BAE_WinPulldwn
			 || bae_swconfig(3)==BAE_MotifPdwn
					/* BAE Pulldown menus software flag */;

// Main program
void main()
{
	double gx, gy			/* Grid dimensions */;
	double msx, msy			/* Mouse workspace coordinates */;
	double mxoff, myoff		/* Mouse position offset */;
	double wlx, wux			/* Window hor. boundary */;
	double wly, wuy			/* Window ver. boundary */;
	double wcx, wcy			/* Window center coordinates */;
	double xshrink, yshrink		/* Shrink values */;
	double curzoom			/* Current zoom factor */;
	int warpmode	= 0		/* Mouse coordinate warp mode */;
	int rangedis			/* Range check disabled flag */;
	// Check if right mouse button activation notification
	if (bae_peekiact() && bae_getactmenu()<0) {
		askstr("",1024);
		bae_getbackgrid(gx,gy);
		bae_getdblpar(2,curzoom);
		if (gx>SMALLVAL && gy>SMALLVAL &&
		 (gx*curzoom<MINGRIDSTEP || gy*curzoom<MINGRIDSTEP)) {
			bae_setdblpar(2,(MINGRIDSTEP/(gx>gy ? gy : gx)));
			exit(0);
			}
		}
	// Abort if invalid plan class
	if (bae_planddbclass()==DDBCLUNDEF)
		error_class();
	// Get current workspace window dimension
	wlx=bae_wswinlx(); wly=bae_wswinly();
	wux=bae_wswinux(); wuy=bae_wswinuy();
	// Check window size
	if (wlx==wux || wly==wuy)
		error_class();
	// Get the mouse workspace position
	bae_wsmouse(msx,msy,0);
	// Check if mouse within workspace window
	if (msx>wlx && msx<wux && msy>wly && msy<wuy) {
		// Get the window center
		wcx=0.5*(wlx+wux);
		wcy=0.5*(wly+wuy);
		// Get the mouse to center offset
		mxoff=msx-wcx;
		myoff=msy-wcy;
		// Check if pulldown menu
		if (PULLDOWN && !bae_iniintval(PAR_ZOOMCENTER,0)) {
			mxoff*=0.5;
			myoff*=0.5;
			}
		else {
			warpmode=4;
			}
		// Add the mouse center offset
		wlx+=mxoff;
		wux+=mxoff;
		wly+=myoff;
		wuy+=myoff;
		}
	// Calculate the shrink values
	xshrink=0.25*(wux-wlx)/0.95;
	yshrink=0.25*(wuy-wly)/0.95;
	// Update the windows dimension
	wlx+=xshrink; wly+=yshrink;
	wux-=xshrink; wuy-=yshrink;
	// Call the Zoom Window command
	bae_clriactqueue();
	bae_storemouseiact(3,wlx,wly,0,LMB);
	bae_storemouseiact(3,wux,wuy,0,LMB);
	call(MNU_BAEZOOMWND);
	// Ensure centered mouse for side menu
	if (warpmode) {
		// Disable range check
		bae_getintpar(0,rangedis);
		bae_setintpar(0,1);
		bae_clriactqueue();
		bae_storemouseiact(3,0.5*(wlx+wux),0.5*(wly+wuy),warpmode,LMB);
		bae_inpoint(0.0,0.0,0.0,0.0,0);
		// Restore old range check state
		bae_setintpar(0,rangedis);
		}
	// Clear dialog line
	bae_prtdialog("");
}

// User Language program end