/* CONUTIL (GED) -- Net List Functions */
/* CONUTIL (GED) -- Netzlistenfunktionen */
/* -- INTENDED FOR KEY-CALL USE -- */
/*
// Copyright (c) 1993-2012 Oliver Bartels F+E, Muenchen
// Author: Manfred Baumeister
// Changes History:
//	rl (120427) RELEASED FOR BAE V7.8.
//	rl (101019) RELEASED FOR BAE V7.6.
//	rl (100331) ENHANCEMENT:
//		Added net pin list with zoom functionality to net assistent.
//	rl (100115) ENHANCEMENT:
//		Added pick part net selection option.
//	rl (091020) RELEASED FOR BAE V7.4.
//	rl (090507) ENHANCEMENT:
//		Added trace length/width and via count violations to report.
//	rl (090304) ENHANCEMENT:
//		Added net pin count options to net assistant.
//	rl (081014) RELEASED FOR BAE V7.2.
//	rl (071029) RELEASED FOR BAE V7.0.
//	rl (071025) ENHANCEMENT:
//		Added trace/via data display to net data report.
//	rl (071015) ENHANCEMENT:
//		Added part level traces to net bounding box scan.
//	rl (070921) ENHANCEMENT:
//		Added attribute support to net assistant.
//	rl (070504) ENHANCEMENT:
//		Added unrouted/routed nets highlight options.
//	rl (070126) ENHANCEMENT:
//		Added net assistant dialog box.
//	rl (060829) RELEASED FOR BAE V6.8.
//	rl (050906) RELEASED FOR BAE V6.6.
//	rl (050510) ENHANCEMENT:
//		Added net attribute search function.
//	rl (041022) ENHANCEMENT:
//		Added net manipulation options to net highlight functions.
//	rl (040831) RELEASED FOR BAE V6.4.
//	rl (030904) RELEASED FOR BAE V6.2.
//	rl (030410) ENHANCEMENT:
//		Added skip to net option in all net highlight.
//	rl (021209) RELEASED FOR BAE V6.0.
//	rl (021017) ENHANCEMENT:
//		Introduced generic net name selection box.
//	rl (020618) RELEASED FOR BAE V5.4.
//	rl (010625) RELEASED FOR BAE V5.0.
//	rl (000508) RELEASED FOR BAE V4.6.
//	rl (990625) RELEASED FOR BAE V4.4.
//	rl (990503) ENHANCEMENT:
//		Added abort with highlight option for "Highlight Nets".
//	rl (980910) RELEASED FOR BAE V4.2.
//	mb (980712) ENHANCEMENT:
//		Pulldown menu delimiters introduced.
//	mb (980712) ENHANCEMENT:
//		Dynamic multi-language support introduced.
//	rl (970929) RELEASED FOR BAE V4.0.
//	mb (960919) RELEASED FOR BAE V3.4.
//	mb (950913) IMPROVEMENT:
//		Introduced scan function with pin scan to zoomtonet()
//		in order to find and display single pin nets.
//	mb (95) RELEASED FOR BAE V3.2.
//	mb (941114) ENHANCEMENT:
//		Introduced zoom to signal functions ("All Nets/Zoom",
//		"Named Nets/Zoom") to the "Highlight Nets" menu.
//	mb (940614) BUGFIX:
//		Net data report to re-init pin count before net pin listing.
//	mb (94) RELEASED FOR BAE V3.0.
//	mb (94) ORIGINAL CODING:
//		integrated ALLNETHL, NETHIGHL, NETDATA, UPDPART.
//	mb (93) RELEASED FOR BAE V2.6.
//	mb (93) ORIGINAL CODING.
//
// DESCRIPTION
//
// The conutil User Language program activates a menu with a
// series of advanced netlist functions such as net data report,
// net highlight, open pins report, netlist check, etc.
*/

// Includes
#include "pop.ulh"			// User Language popup utilities
#include "lay.ulh"			// User Language layout utilities

// Disable undo state request
#pragma ULCALLERNOUNDO

// Messages
string UPRABORT		= M_UPRABORT();
string REPNET		= M("Netz : '","Net : '");
string REPNONET		= M("(nicht gefunden)","(not found)");
string REPNETNAME	= M("Netz ............: '%s'",
			    "Net ............: '%s'");
string REPNUMBER	= M("   Nummer .......: %d","   Number ......: %d");
string REPVIAS		= M("   Vias .........: %d","   Vias ........: %d");
string REPVIASV		= M("!  Vias .........: %d > Netzlimit %d",
			    "!  Vias ........: %d > Net limit %d");
string REPTRACES	= M("   Bahnen .......: %d","   Traces ......: %d");
string REPLENGTH	= M("   Gesamtlaenge..: %s %s",
			    "   Total length : %s %s");
string REPLENGTHV	= M("!  Gesamtlaenge..: %s %s > Netzlimit %s %s",
			    "!  Total length : %s %s > Netz limit %s %s");
string REPWIDTH		= M("   Bahnbreite ...: %s %s",
			    "   Trace width .: %s %s");
string REPWIDTHV	= M("!  Bahnbreite ...: %s %s < Netzmindestvorgabe %s %s",
			    "!  Trace width .: %s %s < Netz min. width %s %s");
string REPMWIDTH	= M("   Bahnbreite ...: min. %s %s max. %s %s",
			    "   Trace width .: min. %s %s max. %s %s");
string REPMWIDTHV	= M("!  Bahnbreite ...: min. %s %s max. %s %s < Netzmindestvorgabe %s %s",
			    "!  Trace width .: min. %s %s max. %s %s < Net min. width %s %s");
string REPPRIOR		= M("   Prioritaet ...: %d","   Priority ....: %d");
string REPDISTDEF	= M("   Abstand ......: default",
			    "   Distance ....: default");
string REPDIST		= M("   Abstand ......: %s %s",
			    "   Distance ....: %s %s");
string REPPINCNT	= M("   Pins .........: %d","   Pins ........: %d");
string REPATTRIB	= "   %s %.*s: '%s'";
string REPUPLACED	= M(" (unpl.)"," (unpl.)");
string REPNPRIO		= M("Prioritaet","Priority");
string REPNDIST		= M("Mindestabstand","Clearance");
string REPNRWIDTH	= M("Bahnbreitenvorgabe","Trace Width");
string REPNNUMBER	= M("Netznummer","Net Number");
string REPUPDPART	= M("Geaenderte Gehaeusezuweisungen",
			    "Changed Package Assignments");
string REPPACKHD1	= M("Bauteil         Makro Netzliste Makro Platziert",
			    "Part            Macro Netlist   Macro Placed");
string REPNOUPDPART	= M("Keine Bauteile mit falschen Gehaeusezuweisungen gefunden!",
			    "No Parts with wrong Package Assignments found!");
string REPSCANATT	= M("Scannen Bauteile/Attribute...",
			    "Scanning parts/attributes...");
string REPATTL		= M("Definierte Attribute :","Defined Attributes : ");
string REPATTVALL	= M("Attributwerte zu '%s' :",
			    "Attribute values for '%s' : ");
string REPNETL		= M("Gefundene Netze :","Matching Nets : ");
string REPNETLIST	= M("%s%s%d Pins","%s%s%d Pins");
string REPNETLISTS	= M("%s%s%d Pin","%s%s%d Pin");
string WRNNOPINATT	= M("Keine Pinattribute definiert!",
			    "No pin attributes defined!");
string WRNNOPARTATT	= M("Keine Bauteilattribute definiert!",
			    "No part attributes defined!");
string WRNNONETS	= M("Keine Netze mit Wert '%s' fuer Attribut '%s' gefunden!",
			    "No nets with value '%s' for attribute '%s' found!");
string WRNNOATTRVAL	= M("Keine Werte fuer Attribut '%s' definiert!",
			    "No attribute value definitions for '%s' found!");
string WRNWPINSET1	= M("Info: Nur %d der %d Pins des Netzes '%s'",
			    "Info: Only %d out of %d pins of net '%s'");
string WRNWPINSET2	= M(" haben die gewaehlte Anschlussbreite %s mm!",
			    " have definied %s mm as routing width!");
string UPRFCT		= M("Funktion selektieren!","Select Function!");
string UPRFCT1		= M("&Highlight Netze","&Highlight Nets");
string UPRFCT2		= M("%&Report Netzdaten","%&Report Net Data");
string UPRFCT3		= M("Report Pin&status","Report Pin &Status");
string UPRFCT4		= M("%Pruefen &Gehaeuse","%Check &Part Types");
string UPRFCT5		= M("&Pruefen Netzliste","&Check Net List");
string UPRFCT6		= M("%&Netzlisten-Ausgabe","%&Net List Output");
string UPRFCT7		= M("%Netzlisten&assistent","%Net List &Assistant");
string UPRHLFCT		= M("Highlight-Funktion selektieren!",
			    "Select Net Highlight Function!");
string UPRHLALL		= M("A&lle Netze","&All Nets");
string UPRHLNAM		= M("Benannte &Netze","Named &Nets");
string UPRHLALLZ	= M("%Alle Netze/&Zoom","%All Nets/&Zoom");
string UPRHLNAMZ	= M("Benannte Netze/Z&oom","Named Nets/Z&oom");
string UPRHLUNROUT	= M("%&Ungeroutete Netze","%&Unrouted Nets");
string UPRHLROUT	= M("&Geroutete Netze","&Routed Nets");
string UPRHLATTZ	= M("%Attribut&suche/Zoom","%Attribute &Search/Zoom");
string UPRHLSAV1	= M("%Highlight/&Farben Laden",
			    "%Load &Highlight/Colors");
string UPRHLSAV2	= M("Highlight/F&arben Speichern",
			    "Save H&ighlight/Colors");
string UPRHLSAV3	= M("Highlight/Farben Loes&chen",
			    "Dele&te Highlight/Colors");
string UPRHLSAV4	= M("%S&ichtbarkeit Laden","%&Load Visibility");
string UPRHLSAV5	= M("Sic&htbarkeit Speichern","Save &Visibility");
string UPRHLSAV6	= M("Sichtbarkeit Lo&eschen","&Delete Visibility");
string UPRCONTX		= M("'  (<CR>:Weiter, <A>:Abbruch) ",
			    "'  (<CR>:Continue, <X>:Abort) ");
string UPRCONTY		= M("'  (<CR>:Weiter, <F>: Funktionsliste,<A>:Abbruch) ",
			    "'  (<CR>:Continue, <F>: Function List, <X>:Abort) ");
string UPRNFCT1		= M("&a Abbruch","&a Abort");
string UPRNFCT2		= M("&h Abbruch mit Highlight",
			    "&h Abort with Highlight");
string UPRNFCT3		= M("&x Netzbahnen fixieren","&x Fix Net");
string UPRNFCT4		= M("&u Netzbahnen freigeben","&u Unfix Net");
string UPRNFCT5		= M("&d Netzbahnen loeschen","&u Delete Net");
string UPRNFCT6		= M("&s Netz Bahnbreiten setzen",
			    "&s Set Net Trace Width");
string UPRNFCT7		= M("&- Vorheriges Netz","&- Previous Net");
string UPRNETNAME	= M("Netzname ? ","Net Name ? ");
string UPRSELANAM	= M("Attributname ? ","Attribute Name ?");
string UPRSELAVAL	= M("Attributwert(smuster) ? ",
			    "Attribute Value (Pattern) ?");
string UPRPINCNT	= M("Anzahl Pins ? ","Pin Count ?");
string UPRMINPINCNT	= M("Mindestanzahl Pins ? ","Minimum Pin Count ?");
string UPRMAXPINCNT	= M("Maximalanzahl Pins ? ","Maximum Pin Count ?");
string UINSTOP		= M("a","x");
string UINHIGHL		= M("h","h");
string UINFUNC		= M("f","f");
string UINPREV		= M("-","-");
string UINFIX		= M("x","x");
string UINUNFIX		= M("u","u");
string UINDELETE	= M("d","d");
string UINSIZE		= M("s","s");
string UPRTRCWM		= M("Bahnbreite [mm] ? ","Trace Width [mm] ? ");
string UPRTRCWI		= M("Bahnbreite [Inch] ? ","Trace Width [Inch] ? ");
string UPRNETFUNC	= M("Netzfunktionen","Net Functions");
string UPRNETDFUNC	= M("Doppelklick :","Double Click :");
string UPRHIGHLIGHT	= M("Highlight","Highlight");
string UPRHLTOGGLE	= M("Netz ein/aus","Toggle Net");
string UPRNHLTOGGLE	= M("Highlight ein/aus","Toggle Highlight");
string UPRHLFOCUS	= M("Fokus ein/aus","Toggle Focus");
string UPRHLRESET	= M("Alle aus","Reset All");
string UPRMCTOGGLE	= M("Airline ein/aus","Toggle Airline");
string UPRMCON		= M("Alle ein","Enable All");
string UPRHLCOLOR	= M("Einfaerbung","Color Net");
string UPRHLLOAD	= M("L","L");
string UPRHLSAVE	= M("S","S");
string UPRCOLPICK	= M("B","B");
string UPRCOL0		= M("keine Farbe","No color");
string UPRCOL1		= M("blau","blue");
string UPRCOL2		= M("gruen","green");
string UPRCOL3		= M("kobaltblau","cyan");
string UPRCOL4		= M("rot","red");
string UPRCOL5		= M("violett","magenta");
string UPRCOL6		= M("braun","brown");
string UPRCOL7		= M("hellgrau","light grey");
string UPRCOL8		= M("dunkelgrau","dark grey");
string UPRCOL9		= M("hellblau","light blue");
string UPRCOL10		= M("hellgruen","light green");
string UPRCOL11		= M("hellkobaltblau","light cyan");
string UPRCOL12		= M("hellrot","light red");
string UPRCOL13		= M("hellviolett","light magenta");
string UPRCOL14		= M("gelb","yellow");
string UPRCOL15		= M("weiss","white");
string UPRPOUTLINE	= M("Kontur","Outline");
string UPRPFILLED	= M("Gefuellt","Filled");
string UPRPDOTTED	= M("Gestrichelt","Dotted");
string UPRPATTERN	= M("Muster %d","Pattern %d");
string UPRZOOMTO	= M("Zoom zu","Zoom to");
string UPRZOOMLAST	= M("Zoom alt","Zoom Last");
string UPRZOOMALL	= M("Zoom Uebersicht","Zoom All");
string UPRNETPICK	= M("Pick","Pick");
string UPRNETINFO	= M("Report Netzdaten","Report Net Data");
string UPRAUTOFOCUS	= M("Autofokus","Autofocus");
string UPRUNETDATA	= M("Netzdaten:","Net Data:");
string UPRNNETDATA	= M("Netzdaten zu '%s':","Net Data of '%s':");
string UPRNETPINS	= M("Netzpins:","Net Pins:");
string UPRNNETPINS	= M("Netzpins zu '%s':","Net Pins of '%s':");
string UPRSELECT	= M("Selektieren","Select");
string UPRDESELECT	= M("Deselektieren","Deselect");
string UPRADDCF		= M("Fuellbereich","Copper Fill Area");
string UPRADDAC		= M("Potentialflaeche","Active Copper");
string UPRMADDCF	= M("Neuer &Fuellbereich","Add Copper &Fill Area");
string UPRMADDAC	= M("&Potentialflaeche"  ,"Add &Active Copper");
string UPRLAYER		= M("Lage","Layer");
string UPRNOLAYER	= M("Keine Lagenvorgabe","No Layer Default");
string UPRSELLAY	= M("Lage waehlen!","Select Layer!");
string UPRNETDATA	= M("Netzdaten '%s'","Net Data '%s'");
string UPRSELATTR	= M("$ - Attributauswahl","$ - Attribute Selection");
string UPRATYP		= M("Attributtyp selektieren!","Select Attibute Type!");
string UPRATYP1		= M("&Netzattribut","&Net Attribute");
string UPRATYP2		= M("&Bauteilattribut","&Part Attribute");
string UPRATYP3		= M("&Pinattribut","P&in Attribute");
string UPRATYP4		= M("%Bau&teilnetze","%Pa&rt Nets");
string UPRATYP5		= M("%Pin&anzahl","%Pin &Count");
string UPRATYP6		= M("M&indestpinanzahl","&Minimum Pin Count");
string UPRATYP7		= M("M&aximalpinanzahl","M&aximum Pin Count");
string UPRATYP8		= M("%Netzname &$","%Net Name &$");
string UPRSELPART	= M("Bauteil selektieren!","Select Part!");
string ERRDBLNETDB	= M("Netzassistent ist bereits aktiv!",
			    "Net Assistant already active!");
string ERRNOWIN		= M("Nur in Windowsumgebungen verfuegbar!",
			    "Windows Environment needed!");
string ERRINPVAL	= M_ERRINPVAL();
string ITMPRT		= M("Bauteil","Part");
string ITMPIN		= M("Pin","Pin");
string ITMWIDTH		= M("Breite","Width");
#define REPPINH1	"%-*s %-*s %-*s"
#define REPPINH2	"%.*s %.*s %.*s"
#define REPPIN		"%-*s %-*s %*s"
#define ITMULINE	"========================================"
#define REPPACKHD2	"=============== =============== ==============="
#define REPPACKAGE	"%-15s %-15s %-15s"
#define ITMUDOT		"......................................."
int ATTFLEN		= strlen(REPDIST)-11	/* Attribute field length */;

// INI file parameter name definitions
#define PAR_NETNSEP	"NETNAMESEP_GED"	// Net name seperator
#define PAR_NETBOXH	"NETLISTBOXH_GED"	// Net list box height
#define PAR_INFOBOXH	"NETINFOBOXH_GED"	// Net info list box height
#define PAR_NETINFO	"NETINFODISP_GED"	// Net info display flag
#define PAR_PINBOXH	"NETPINBOXH_GED"	// Net pin list box height
#define PAR_NETPINS	"NETPINDISP_GED"	// Net pin display flag
#define PAR_ZOOMEXP	"PINZOOMEXP_GED"	// Net pin zoom expansion value

// Global User Language program variables
#define UL_UNCONPIN	"unconpin"	// ULP: Report Open Pins
#define UL_CHECKLNL	"checklnl"	// ULP: Check Net List
#define UL_CONBAE	"conbae"	// ULP: Connection List Output
#define UL_NETSTAT	"netstat"	// ULP: Net Highlight Database
#define GV_HLREQUEST	"hlrequest"	// Highlight request variable
#define GV_NAMEFIELD	"na_nameidx"	// Name field index
#define GV_INFOFIELD	"na_infidx"	// Net info field index
#define GV_PINFIELD	"na_pinidx"	// Pin listbox field index
#define GV_PINCNT	"na_pincnt"	// Pin listbox current pin count
#define GV_LAYFIELD	"na_layeridx"	// Layer field index
#define GV_FUNCFIELD	"na_funcidx"	// Function field index
#define GV_COLFIELD	"na_colidx"	// Color index
#define GV_FOCUSFIELD	"na_focusidx"	// Autofocus flag field index
#define GV_LAYNUM	"na_layer"	// Layer code

// Destination unit designators
string UNIT = bae_getcoorddisp() ? "[\"]" : "[mm]";
					// Unit designator

// Globals
#define BUTWIDTH	11.0		// Button width
#define BUTSPC		12.0		// Button spacing
#define COLFIN		2		// Fade in color value
string NETSEP = bae_inistrval(PAR_NETNSEP," ")
					/* Net name seperator */;
double NETBOXH = bae_inidblval(PAR_NETBOXH,6.8)
					/* Net list box height */;
double INFOBOXH = bae_inidblval(PAR_INFOBOXH,6.0)
					/* Net info box height */;
int INFODISP = bae_iniintval(PAR_NETINFO,1)
					/* Net info display flag */;
double PINBOXH = bae_inidblval(PAR_PINBOXH,4.0)
					/* Net pin list box height */;
int PINDISP = bae_iniintval(PAR_NETPINS,1)
					/* Net pin list display flag */;
double ZOOMEXP = bae_inidblval(PAR_ZOOMEXP,0.005)
					/* Net pin zoom window expansion */;
STRINGS headl				/* Header list */;
int headn		= 0		/* Header count */;
STRINGS entryl				/* Entry list */;
int entryn		= 0		/* Entry count */;
double zoomlx,zoomly			/* Zoom lower boundaries */;
double zoomux,zoomuy			/* Zoom upper boundaries */;
int curnetnum				/* Current net tree number */;
string curnetname			/* Current net name */;
string curpinname			/* Current pin name */;
int curnetpn		= 2		/* Current net pin count */;
int curseltyp				/* Current net selection type */;
string curattrname			/* Current attribute name */;
string curattrval			/* Current attribute value */;
double trcminwidth			/* Trace min. width */;
double trcmaxwidth			/* Trace max. width */;
double trcslen				/* Trace scan length */;
int trcscnt				/* Trace scan count */;
int viascnt				/* Via scan count */;
int chgflag		= 0		/* Figure list change flag */;

// Main program
void main()
{
	index L_CNET cnet		/* Net list index */;
	// Abort if invalid plan class
	if (varget(VAR_PDBOXIDX,0) && bae_planddbclass()!=DDBCLLAY)
		error_class();
	// Select connection list function
	bae_promptdialog(UPRFCT);
	switch (bae_askmenu(8,UPRFCT1,UPRFCT2,
	 UPRFCT3,UPRFCT4,UPRFCT5,UPRFCT6,UPRFCT7,UPRABORT)) {
		// Net highlight
		case 0 :
		// Select highlight function
		bae_promptdialog(UPRHLFCT);
		switch (bae_askmenu(14,UPRHLALL,UPRHLNAM,
		 UPRHLALLZ,UPRHLNAMZ,UPRHLUNROUT,UPRHLROUT,UPRHLATTZ,
		 UPRHLSAV1,UPRHLSAV2,UPRHLSAV3,UPRHLSAV4,UPRHLSAV5,UPRHLSAV6,
		 UPRABORT)) {
			// All net highlight
			case 0 :
			allnethighlight(0);
			break;
			// Named net highlight
			case 1 :
			nethighlight(0);
			break;
			// All net highlight with zoom
			case 2 :
			allnethighlight(1);
			break;
			// Named net highlight with zoom
			case 3 :
			nethighlight(1);
			break;
			// Unrouted nets highlight
			case 4 :
			forall (cnet where
			 cnet.PINN>1 && cnet.VIS && cnet.UNRPOOL>=0)
				ged_highlnet(cnet.NUMBER,1);
			break;
			// Routed nets highlight
			case 5 :
			forall (cnet where
			 cnet.PINN>1 && cnet.VIS && cnet.UNRPOOL<0)
				ged_highlnet(cnet.NUMBER,1);
			break;
			// Attribute search net with highlight & zoom
			case 6 :
			netattrsearch();
			break;
			// Net highlight/coloring load
			case 7 :
			bae_storemenuiact(3,0,LMB);
			runulprog(UL_NETSTAT);
			break;
			// Net highlight/coloring save
			case 8 :
			bae_storemenuiact(3,1,LMB);
			runulprog(UL_NETSTAT);
			break;
			// Net highlight/coloring delete
			case 9 :
			bae_storemenuiact(3,2,LMB);
			runulprog(UL_NETSTAT);
			break;
			// Net visibility status load
			case 10 :
			bae_storemenuiact(3,3,LMB);
			runulprog(UL_NETSTAT);
			break;
			// Net visibility status save
			case 11 :
			bae_storemenuiact(3,4,LMB);
			runulprog(UL_NETSTAT);
			break;
			// Net visibility status delete
			case 12 :
			bae_storemenuiact(3,5,LMB);
			runulprog(UL_NETSTAT);
			break;
			}
		break;
		// Report net data
		case 1 :
		netdata();
		break;
		// Report open pins
		case 2 :
		// Run the report open pins program
		runulprogexit(UL_UNCONPIN);
		// Check part types
		case 3 :
		updpartrep();
		break;
		// Check net list
		case 4 :
		// Run the check net list program
		runulprogexit(UL_CHECKLNL);
		// Connection list output
		case 5 :
		// Run the connection list output program
		runulprogexit(UL_CONBAE);
		// Net list assistant
		case 6 :
		netassistant();
		break;
		}
}

// Net highlight routines

void allnethighlight(int zoomflag)
/*
// Highlight all nets step by step
// Parameters :
//	int zoomflag		: Zoom to net request flag
*/
{
	index L_FIGURE fig		/* Figure list index */;
	index L_CNET net		/* Net index */;
	index L_CNET nnet		/* New net index */;
	index L_CNET netl[]		/* Net list */;
	int netn	= 0		/* Net count */;
	string answer			/* Answer string */;
	double width			/* Trace width */;
	int repflag			/* Repeat flag */;
	int i				/* Loop control variable */;
	// Loop for all nets
	forall (net) {
		netl[netn]=net;
		netn++;
		}
	// Loop for all nets
	for (i=0;i<netn;i++) {
		net=netl[i];
		// Highlight net
		ged_highlnet(net.NUMBER,1);
		// Zoom to signal on request
		if (zoomflag)
			zoomtonet(net);
		// Prompt user for continue
		repflag=1;
		while (repflag)
			switch (asknetcontinue(net.NAME,1,answer)) {
				// Abort with highlight
				case 1 :
				// Done
				return;
				// Return to previous net
				case 2 :
				// Dehighlight net
				ged_highlnet(net.NUMBER,0);
				// Skip to previous net
				if (i>0)
					i-=2;
				else
					i--;
				repflag=0;
				break;
				// Fix net
				case 3 :
				// Dehighlight net
				ged_highlnet(net.NUMBER,0);
				// Reset the group
				bae_callmenu(MNU_GEDGRPRESE);
				// Select net
				ged_groupselect(7,net.NUMBER,1);
				// Fix traces and vias
				forall (fig where fig.GROUP && !fig.FIXED &&
				 (fig.TYP==L_FIGPATH || fig.TYP==L_FIGUREF)) {
					// Save current state for undo
					if (!chgflag) {
						bae_callmenu(MNU_BAESAVESTATE);
						chgflag=1;
						}
					ged_elemfixchg(fig,1);
					}
				// Reset the group
				bae_callmenu(MNU_GEDGRPRESE);
				i--;
				repflag=0;
				break;
				// Unfix net
				case 4 :
				// Dehighlight net
				ged_highlnet(net.NUMBER,0);
				// Reset the group
				bae_callmenu(MNU_GEDGRPRESE);
				// Select net
				ged_groupselect(7,net.NUMBER,1);
				// Unfix traces and vias
				forall (fig where fig.GROUP && fig.FIXED &&
				 (fig.TYP==L_FIGPATH || fig.TYP==L_FIGUREF)) {
					// Save current state for undo
					if (!chgflag) {
						bae_callmenu(MNU_BAESAVESTATE);
						chgflag=1;
						}
					ged_elemfixchg(fig,0);
					}
				// Reset the group
				bae_callmenu(MNU_GEDGRPRESE);
				i--;
				repflag=0;
				break;
				// Delete net
				case 5 :
				// Dehighlight net
				ged_highlnet(net.NUMBER,0);
				// Reset the group
				bae_callmenu(MNU_GEDGRPRESE);
				// Select net
				ged_groupselect(7,net.NUMBER,1);
				// Deselect non trace and via elements
				forall (fig where fig.GROUP &&
				 fig.TYP!=L_FIGPATH && fig.TYP!=L_FIGUREF)
					ged_elemgrpchg(fig,0);
				// Delete the group
				bae_callmenu(MNU_GEDDELGRP);
				i--;
				repflag=0;
				break;
				// Set net trace width
				case 6 :
				// Get segment width
				ged_getpathwidth(width,0.0);
				if (askdist(width,lay_defusrunit()?UPRTRCWI:
				 UPRTRCWM,0) || width==0.0)
					// Invalid input value
					error(ERRINPVAL);
				// Reset the group
				bae_callmenu(MNU_GEDGRPRESE);
				// Select net
				ged_groupselect(7,net.NUMBER,1);
				// Change trace width
				forall (fig where fig.GROUP &&
				 fig.TYP==L_FIGPATH) {
					// Save current state for undo
					if (!chgflag) {
						bae_callmenu(MNU_BAESAVESTATE);
						chgflag=1;
						}
					ged_elemsizechg(fig,width);
					}
				// Reset the group
				bae_callmenu(MNU_GEDGRPRESE);
				i--;
				repflag=0;
				break;
				// Abort without highlight
				case (-1) :
				// Dehighlight net
				ged_highlnet(net.NUMBER,0);
				return;
				default :
				// Dehighlight net
				ged_highlnet(net.NUMBER,0);
				if (answer!="") {
					// Try to locate net
					if (lay_findcontree(answer,nnet)==0)
						lay_findcontree(answer,net);
					// Highlight net
					ged_highlnet(net.NUMBER,1);
					// Zoom to signal on request
					if (zoomflag)
						zoomtonet(net);
					}
				else {
					repflag=0;
					}
				}
		}
	// Done
}

void nethighlight(int zoomflag)
/*
// Highlight Named Nets
// Parameters :
//	int zoomflag		: Zoom to net request flag
*/
{
	index L_CNET net		/* Net index */;
	index L_FIGURE fig		/* Figure list index */;
	string netname			/* Net name */;
	string answer			/* Answer string */;
	double width			/* Trace width */;
	int res				/* Result code */;
	// Repetively select named nets
	while ((res=ged_asktreeidx(netname,net,3))!=(-1)) {
		// Check if valid tree index
		if (res!=0 && res!=3) {
			// Prompt user for continue
			if (asknetcontinue(netname+REPNONET,0,""))
				// Abort request ?
				break;
			continue;
			}
		// Highlight net
		ged_highlnet(net.NUMBER,1);
		answer=bae_peekiact()==2 ? askstr("",MAXKEYLEN) : "" ;
		// Zoom to signal on request
		if (zoomflag)
			zoomtonet(net);
		if (answer!="")
			bae_storetextiact(1,answer);
		// Prompt user for continue
		switch (asknetcontinue(net.NAME,1,"")) {
			// Abort with highlight
			case 1 :
			// Done
			return;
			// Return to previous net
			case 2 :
			break;
			// Fix net
			case 3 :
			// Dehighlight net
			ged_highlnet(net.NUMBER,0);
			// Reset the group
			bae_callmenu(MNU_GEDGRPRESE);
			// Select net
			ged_groupselect(7,net.NUMBER,1);
			// Fix traces and vias
			forall (fig where fig.GROUP && !fig.FIXED &&
			 (fig.TYP==L_FIGPATH || fig.TYP==L_FIGUREF)) {
				// Save current state for undo
				if (!chgflag) {
					bae_callmenu(MNU_BAESAVESTATE);
					chgflag=1;
					}
				ged_elemfixchg(fig,1);
				}
			// Reset the group
			bae_callmenu(MNU_GEDGRPRESE);
			break;
			// Unfix net
			case 4 :
			// Dehighlight net
			ged_highlnet(net.NUMBER,0);
			// Reset the group
			bae_callmenu(MNU_GEDGRPRESE);
			// Select net
			ged_groupselect(7,net.NUMBER,1);
			// Unfix traces and vias
			forall (fig where fig.GROUP && fig.FIXED &&
			 (fig.TYP==L_FIGPATH || fig.TYP==L_FIGUREF)) {
				// Save current state for undo
				if (!chgflag) {
					bae_callmenu(MNU_BAESAVESTATE);
					chgflag=1;
					}
				ged_elemfixchg(fig,0);
				}
			// Reset the group
			bae_callmenu(MNU_GEDGRPRESE);
			break;
			// Delete net
			case 5 :
			// Dehighlight net
			ged_highlnet(net.NUMBER,0);
			// Reset the group
			bae_callmenu(MNU_GEDGRPRESE);
			// Select net
			ged_groupselect(7,net.NUMBER,1);
			// Deselect non trace and via elements
			forall (fig where fig.GROUP &&
			 fig.TYP!=L_FIGPATH && fig.TYP!=L_FIGUREF)
				ged_elemgrpchg(fig,0);
			// Delete the group
			bae_callmenu(MNU_GEDDELGRP);
			break;
			// Set net trace width
			case 6 :
			// Get segment width
			ged_getpathwidth(width,0.0);
			if (askdist(width,lay_defusrunit()?UPRTRCWI:
			 UPRTRCWM,0) || width==0.0)
				// Invalid input value
				error(ERRINPVAL);
			// Reset the group
			bae_callmenu(MNU_GEDGRPRESE);
			// Select net
			ged_groupselect(7,net.NUMBER,1);
			// Change trace width
			forall (fig where fig.GROUP &&
			 fig.TYP==L_FIGPATH) {
				// Save current state for undo
				if (!chgflag) {
					bae_callmenu(MNU_BAESAVESTATE);
					chgflag=1;
					}
				ged_elemsizechg(fig,width);
				}
			// Reset the group
			bae_callmenu(MNU_GEDGRPRESE);
			break;
			// Abort without highlight
			case (-1) :
			// Dehighlight net
			ged_highlnet(net.NUMBER,0);
			return;
			default :
			;
			}
		// Dehighlight net
		ged_highlnet(net.NUMBER,0);
		}
	// Done
}

void netattrsearch()
/*
// Search Nets
*/
{
	index L_CNET net		/* Net index */;
	index L_CPIN pin		/* Connection pin index */;
	index L_ATTRIBUTE att		/* Attribute index */;
	index L_FIGURE fig		/* Figure list index */;
	string netname			/* Net name */;
	string attnam			/* Attribute name */;
	string attval			/* Attribute value */;
	string prompt	= ""		/* Prompt string */;
	string answer			/* Answer string */;
	double width			/* Trace width */;
	int tpn				/* Total net pin count */;
	int spn				/* Selected net pin count */;
	// Build attribute name list
	bae_prtdialog(REPSCANATT);
	entryn=0;
	gcname(REPNNUMBER);
	gcname(REPNPRIO);
	forall (net)
		forall (att of net)
			gcname(att.NAME);
	forall (net where net.RDIST!=0.0) {
		gcname(REPNDIST);
		break;
		}
	forall (net)
		forall (pin of net where pin.RWIDTH!=0.0) {
			gcname(REPNRWIDTH);
			break;
			}
	// Build the attribute selection popup menu
	headl[0]=REPATTL;
	headl[1]="";
	headn=2;
	// Select net attribute name to be searched
	bae_setintpar(16,3050);
	if ((attnam=popupmenu(4,UPRSELANAM,headl,headn,entryl,entryn,
	 UINPOPABORT,0,-1,-1,0,0,0,UINPOPABORT))=="" || attnam==UINPOPABORT)
		error_abort();
	// Build attribute value list
	bae_prtdialog(REPSCANATT);
	entryn=0;
	switch (attnam) {
		case REPNPRIO :
		forall (net)
			gcname(itoa(net.PRIOR));
		break;
		case REPNUMBER :
		forall (net)
			gcname(itoa(net.NUMBER));
		break;
		case REPNDIST :
		forall (net where net.RDIST!=0.0)
			gcname(bae_numstring(cvtlength(net.RDIST,0,2),5));
		break;
		case REPNRWIDTH :
		forall (net)
		    forall (pin of net where pin.RWIDTH!=0.0)
			gcname(bae_numstring(cvtlength(pin.RWIDTH,0,2),5));
		break;
		default :
		if (attnam[0]!='$')
			error_abort();
		forall (net)
			forall (att of net where att.NAME==attnam)
				gcname(att.VALUE);
		}
	// Abort with warning if no attribute values found
	if (entryn==0) {
		sprintf(prompt,WRNNOATTRVAL,attnam);
		bae_msgbox(0,prompt,"");
		return;
		}
	// Build the attribute selection popup menu
	sprintf(headl[0],REPATTVALL,attnam);
	// Select net attribute value to be searched
	bae_setintpar(16,3051);
	if ((attval=popupmenu(4,UPRSELAVAL,headl,headn,entryl,entryn,
	 UINPOPABORT,0,-1,-1,0,0,0,UINPOPABORT))==UINPOPABORT)
		error_abort();
	// Store all matching nets
	entryn=0;
	switch (attnam) {
		case REPNPRIO :
		forall (net)
			if (attval==itoa(net.PRIOR))
				gcname(net.NAME);
		break;
		case REPNNUMBER :
		forall (net)
			if (attval==itoa(net.NUMBER))
				gcname(net.NAME);
		break;
		case REPNDIST :
		forall (net)
			if (attval==bae_numstring(cvtlength(net.RDIST,0,2),5))
				gcname(net.NAME);
		break;
		case REPNRWIDTH :
		forall (net)
		    forall (pin of net)
			if (attval==
			 bae_numstring(cvtlength(pin.RWIDTH,0,2),5)) {
				gcname(net.NAME);
				break;
				}
		break;
		default :
		forall (net)
			// Search attribute
			forall (att of net where att.NAME==attnam &&
			 (strmatch(att.VALUE,attval) || att.VALUE==attval)) {
				gcname(net.NAME);
				break;
				}
		}
	// Check if nets found
	if (entryn==0) {
		sprintf(prompt,WRNNONETS,attval,attnam);
		bae_msgbox(0,prompt,"");
		return;
		}
	// Build the net selection popup menu
	headl[0]=REPNETL;
	headl[1]="";
	headn=2;
	// Repetively select named nets
	bae_setintpar(16,3062);
	while ((netname=popupmenu(1,UPRNETNAME,headl,headn,
	  entryl,entryn,UINPOPABORT,0,-1,-1,0,0,0,UINPOPABORT))!="" &&
	 netname!=UINPOPABORT) {
		// Check if valid tree index
		if (lay_findcontree(netname,net)!=0) {
			// Prompt user for continue
			if (asknetcontinue(netname+REPNONET,0,""))
				// Abort request ?
				break;
			continue;
			}
		// Check if routing width attribute
		if (attnam==REPNRWIDTH) {
			tpn=spn=0;
			forall (pin of net) {
				tpn++;
				if (attval==
				 bae_numstring(cvtlength(pin.RWIDTH,0,2),5))
					spn++;
				}
			if (tpn!=spn) {
				sprintf(prompt,WRNWPINSET1+WRNWPINSET2,spn,tpn,
				 netname,attval);
				bae_msgbox(0,prompt,"");
				}
			}
		// Highlight net
		ged_highlnet(net.NUMBER,1);
		answer=bae_peekiact()==2 ? askstr("",MAXKEYLEN) : "" ;
		// Zoom to signal
		zoomtonet(net);
		if (answer!="")
			bae_storetextiact(1,answer);
		// Prompt user for continue
		switch (asknetcontinue(net.NAME,1,"")) {
			// Abort with highlight
			case 1 :
			// Done
			return;
			// Return to previous net
			case 2 :
			break;
			// Fix net
			case 3 :
			// Dehighlight net
			ged_highlnet(net.NUMBER,0);
			// Reset the group
			bae_callmenu(MNU_GEDGRPRESE);
			// Select net
			ged_groupselect(7,net.NUMBER,1);
			// Fix traces and vias
			forall (fig where fig.GROUP && !fig.FIXED &&
			 (fig.TYP==L_FIGPATH || fig.TYP==L_FIGUREF)) {
				// Save current state for undo
				if (!chgflag) {
					bae_callmenu(MNU_BAESAVESTATE);
					chgflag=1;
					}
				ged_elemfixchg(fig,1);
				}
			// Reset the group
			bae_callmenu(MNU_GEDGRPRESE);
			break;
			// Unfix net
			case 4 :
			// Dehighlight net
			ged_highlnet(net.NUMBER,0);
			// Reset the group
			bae_callmenu(MNU_GEDGRPRESE);
			// Select net
			ged_groupselect(7,net.NUMBER,1);
			// Unfix traces and vias
			forall (fig where fig.GROUP && fig.FIXED &&
			 (fig.TYP==L_FIGPATH || fig.TYP==L_FIGUREF)) {
				// Save current state for undo
				if (!chgflag) {
					bae_callmenu(MNU_BAESAVESTATE);
					chgflag=1;
					}
				ged_elemfixchg(fig,0);
				}
			// Reset the group
			bae_callmenu(MNU_GEDGRPRESE);
			break;
			// Delete net
			case 5 :
			// Dehighlight net
			ged_highlnet(net.NUMBER,0);
			// Reset the group
			bae_callmenu(MNU_GEDGRPRESE);
			// Select net
			ged_groupselect(7,net.NUMBER,1);
			// Deselect non trace and via elements
			forall (fig where fig.GROUP &&
			 fig.TYP!=L_FIGPATH && fig.TYP!=L_FIGUREF)
				ged_elemgrpchg(fig,0);
			// Delete the group
			bae_callmenu(MNU_GEDDELGRP);
			break;
			// Set net trace width
			case 6 :
			// Get segment width
			ged_getpathwidth(width,0.0);
			if (askdist(width,lay_defusrunit()?UPRTRCWI:
			 UPRTRCWM,0) || width==0.0)
				// Invalid input value
				error(ERRINPVAL);
			// Reset the group
			bae_callmenu(MNU_GEDGRPRESE);
			// Select net
			ged_groupselect(7,net.NUMBER,1);
			// Change trace width
			forall (fig where fig.GROUP &&
			 fig.TYP==L_FIGPATH) {
				// Save current state for undo
				if (!chgflag) {
					bae_callmenu(MNU_BAESAVESTATE);
					chgflag=1;
					}
				ged_elemsizechg(fig,width);
				}
			// Reset the group
			bae_callmenu(MNU_GEDGRPRESE);
			break;
			// Abort without highlight
			case (-1) :
			// Dehighlight net
			ged_highlnet(net.NUMBER,0);
			return;
			default :
			;
			}
		// Dehighlight net
		ged_highlnet(net.NUMBER,0);
		}
	// Done
}

void zoomtonet(index L_CNET net)
/*
// Zoom to a signal specified by net number
// Parameter :
//	index L_CNET net	: Net index
*/
{
#define WEL		0.001		// Window enlarge length
	string hlreq			/* Highlight request net name */;
	string msg			/* Message string */;
	int netnum	= net.NUMBER	/* Net number */;
	// Init boundaries out of range
	zoomlx=bae_planwsux()+10.0;
	zoomly=bae_planwsuy()+10.0;
	zoomux=bae_planwslx()-10.0;
	zoomuy=bae_planwsly()-10.0;
	// Set the current global net number
	curnetnum=netnum;
	// Scan the pins
	if (lay_scanall(0.0,0.0,0.0,0,1,
	 pinscan,NULL,pathscan,NULL,NULL,NULL,NULL))
		error_scan();
	// Scan the unroutes
	if (lay_scanpool(net.UNRPOOL,0.0,0.0,0.0,0,0,
	 NULL,NULL,upathscan,NULL,NULL,NULL,NULL))
		error_scan();
	// Abort if invalid zoom range
	if (zoomlx-WEL>zoomux || zoomly-WEL>zoomuy)
		return;
	// Zoom to calculated boundaries
	bae_clriactqueue();
	bae_storemouseiact(1,zoomlx-WEL,zoomly-WEL,0,LMB);
	bae_storemouseiact(1,zoomux+WEL,zoomuy+WEL,0,LMB);
	call(MNU_BAEZOOMWND);
	if (varget(GV_HLREQUEST,hlreq))
		hlreq="";
	if (hlreq!=net.NAME) {
		// Build the highlight/zoom to net request message
		sprintf(msg,"%d %s",MSGID_NETZOOMHL,net.NAME);
		// Send the highlight/zoom to net request message
		bae_sendmsg(msg,1);
		}
	vardelete(GV_HLREQUEST);
}

int pinscan(index L_MACRO macro,index L_POOL pool,
 int macinws,string refname,index L_LEVEL level)
/*
// Pin macro scan function
// Return value :
//	0 if out of workspace, 1 if inside, 2 if unknown, or (-1) on error
// Parameters :
//	index L_MACRO macro	: Macro index
//	index L_POOL pool	: Macro pool index
//	int macinws		: Macro in workspace flag
//	string refname		: Macro reference name
//	index L_LEVEL level	: Macro level
*/
{
	double x,y			/* Macro coordinates */;
	double a			/* Macro rotation angle */;
	int m				/* Macro mirror flag */;
	int l				/* Macro layer number */;
	int stktree			/* Padstack tree number */;
	// Continue scan for part macros
	if (macro.CLASS==DDBCLLPRT)
		return(1);
	// Test if padstack macro
	if (macro.CLASS==DDBCLLSTK) {
		// Get the padstack tree number from level
		if ((stktree=lay_getlevtreenum(level))<0)
			// Invalid level tree
			stktree=(-1);
		// Test if padstack matches current net number
		if (stktree==curnetnum) {
			// Get macro coordinates
			lay_maccoords(x,y,a,m,l);
			// Update the zoom range
			if (zoomlx>x) zoomlx=x;
			if (zoomux<x) zoomux=x;
			if (zoomly>y) zoomly=y;
			if (zoomuy<y) zoomuy=y;
			}
		}
	// Abort scan
	return(0);
}

int pathscan(index L_LINE path,int layer,int pathinws,index L_LEVEL level)
/*
// Path scan function
// Return value :
//	zero if done, or (-1) on error
// Parameters :
//	index L_LINE path	: Path index
//	int layer		: Path layer
//	int pathinws		: Path in workspace flag
//	index L_LEVEL level	: Path level
*/
{
	index L_POINT point		/* Point index */;
	int trctree			/* Trace tree number */;
	double lx,ly,ux,uy		/* Zoom boundaries */;
	// Get the trace tree number from level
	if ((trctree=lay_getlevtreenum(level))<0)
		// Invalid level tree
		trctree=(-1);
	if (trctree==curnetnum) {
		// Loop for path points
		bae_clearpoints();
		forall (point of path)
			// Store point to internal list
			bae_storepoint(point.X,point.Y,point.TYP);
		// Get the polygon range
		bae_getpolyrange(lx,ly,ux,uy);
		// Update net range
		if (zoomlx>lx) zoomlx=lx;
		if (zoomux<ux) zoomux=ux;
		if (zoomly>ly) zoomly=ly;
		if (zoomuy<uy) zoomuy=uy;
		}
	// Return without errors
	return(0);
}

int upathscan(index L_LINE path,int layer,int pathinws,index L_LEVEL level)
/*
// Path (unroutes) scan function
// Return value :
//	zero if done, or (-1) on error
// Parameters :
//	index L_LINE path	: Path index
//	int layer		: Path layer
//	int pathinws		: Path in workspace flag
//	index L_LEVEL level	: Path level
*/
{
	index L_POINT point		/* Point index */;
	// Loop for all path points
	forall (point of path) {
		// Update the zoom boundaries
		if (zoomlx>point.X) zoomlx=point.X;
		if (zoomux<point.X) zoomux=point.X;
		if (zoomly>point.Y) zoomly=point.Y;
		if (zoomuy<point.Y) zoomuy=point.Y;
		}
	// Return without errors
	return(0);
}

int npinscan(index L_MACRO macro,index L_POOL pool,
 int macinws,string refname,index L_LEVEL level)
/*
// Named pin macro scan function
// Return value :
//	0 if out of workspace, 1 if inside, 2 if unknown, or (-1) on error
// Parameters :
//	index L_MACRO macro	: Macro index
//	index L_POOL pool	: Macro pool index
//	int macinws		: Macro in workspace flag
//	string refname		: Macro reference name
//	index L_LEVEL level	: Macro level
*/
{
	double x,y			/* Macro coordinates */;
	// Continue scan for part macros
	if (macro.CLASS==DDBCLLPRT)
		return(1);
	// Test if padstack macro
	if (macro.CLASS==DDBCLLSTK && refname==curpinname) {
		// Get macro coordinates
		lay_maccoords(x,y,0.0,0,0);
		// Perform zoom window to the pin
		bae_clriactqueue();
		bae_storemouseiact(1,x-ZOOMEXP,y-ZOOMEXP,0,LMB);
		bae_storemouseiact(1,x+ZOOMEXP,y+ZOOMEXP,0,LMB);
		call(MNU_BAEZOOMWND);
		}
	// Abort scan
	return(0);
}

// Connection list report routines

void netdata()
/*
// Display Net Data for Named Nets
*/
{
	index L_CNET net		/* Net index */;
	string netname			/* Net name */;
	int res				/* Result code */;
	while ((res=ged_asktreeidx(netname,net,3))!=(-1)) {
		// Check if valid tree index
		if (res!=0 && res!=3) {
			// Prompt user for continue
			if (asknetcontinue(netname+REPNONET,0,""))
				// Abort request ?
				break;
			continue;
			}
		// Display net data
		dispnetdata(net,1);
		}
	// Done
}

void dispnetdata(index L_CNET net,int fullinfo)
/*
// Display Net Data for given net
// Parameter :
//	index L_CNET net	: Net index
//	int fullinfo		: Net full info flag
*/
{
	index L_CPIN pin		/* Pin index */;
	index L_ATTRIBUTE attr		/* Attribute index */;
	string msg			/* Message buffer */;
	STRINGS pl			/* Pin list */;
	int pn				/* Pin count */;
	double tlen			/* Trace length */;
	double minw, maxw		/* Trace min./max. width */;
	int tcnt			/* Trace count */;
	int vcnt			/* via count */;
	int lprt,lpin,lwid		/* Output width values */;
	double maxtrclen		/* Max. allowed trace length */;
	double mintrcwidth		/* Min. requested trace width */;
	int maxviacnt			/* Max. allowed via count */;
	// Get net trace/via data
	tlen=treepathlen(net.NUMBER,tcnt,vcnt,minw,maxw);
	maxtrclen=mintrcwidth=(-1.0);
	maxviacnt=(-1);
	forall (attr of net)
		switch (attr.NAME) {
			case "$maxviacnt" :
			if (attr.VALUE!="")
				maxviacnt=atoi(attr.VALUE);
			break;
			case "$maxnetlen" :
			if (attr.VALUE!="")
				maxtrclen=atof_len(attr.VALUE);
			break;
			}
	forall (pin of net)
		if (pin.RWIDTH!=0.0 &&
		 (mintrcwidth<0.0 || pin.RWIDTH<mintrcwidth))
			mintrcwidth=pin.RWIDTH;
	// Display net data
	headn=0;
	if (fullinfo) {
		sprintf(headl[headn],REPNETNAME,net.NAME);
		headn++;
		}
	sprintf(headl[headn],REPNUMBER,net.NUMBER);
	headn++;
	sprintf(headl[headn],REPPRIOR,net.PRIOR);
	headn++;
	if (net.RDIST==0.0)
		sprintf(headl[headn],REPDISTDEF);
	else
		sprintf(
		 headl[headn],REPDIST,bae_numstring(baecvtl(net.RDIST),3),UNIT);
	headn++;
	sprintf(headl[headn],REPPINCNT,net.PINN);
	headn++;
	if (vcnt>0) {
		if (maxviacnt>=0 && vcnt>maxviacnt)
			sprintf(headl[headn],REPVIASV,vcnt,maxviacnt);
		else
			sprintf(headl[headn],REPVIAS,vcnt);
		headn++;
		}
	if (tcnt>0) {
		sprintf(headl[headn],REPTRACES,tcnt);
		headn++;
		if (maxtrclen>=0.0 && tlen>maxtrclen)
			sprintf(headl[headn],REPLENGTHV,
			 bae_numstring(baecvtl(tlen),3),UNIT,
			 bae_numstring(baecvtl(maxtrclen),3),UNIT);
		else
			sprintf(headl[headn],REPLENGTH,
			 bae_numstring(baecvtl(tlen),3),UNIT);
		headn++;
		if (mintrcwidth>=0.0 && minw<mintrcwidth) {
			if (minw==maxw)
				sprintf(headl[headn],REPWIDTHV,
				 bae_numstring(baecvtl(minw),4),UNIT,
				 bae_numstring(baecvtl(mintrcwidth),4),UNIT);
			else
				sprintf(headl[headn],REPMWIDTHV,
				 bae_numstring(baecvtl(minw),4),UNIT,
				 bae_numstring(baecvtl(maxw),4),UNIT,
				 bae_numstring(baecvtl(mintrcwidth),4),UNIT);
			}
		else {
			if (minw==maxw)
				sprintf(headl[headn],REPWIDTH,
				 bae_numstring(baecvtl(minw),4),UNIT);
			else
				sprintf(headl[headn],REPMWIDTH,
				 bae_numstring(baecvtl(minw),4),UNIT,
				 bae_numstring(baecvtl(maxw),4),UNIT);
			}
		headn++;
		}
	forall (attr of net) {
		sprintf(headl[headn],REPATTRIB,attr.NAME,
		 ATTFLEN>strlen(attr.NAME) ?
		  ATTFLEN-strlen(attr.NAME) : 0,
		 ITMUDOT,attr.VALUE);
		headn++;
		}
	if (!fullinfo)
		return;
	// Test if pins defined
	if (net.PINN) {
		// Init the output field widths
		lprt=strlen(ITMPRT);
		lpin=strlen(ITMPIN);
		lwid=strlen(ITMWIDTH+UNIT);
		// Update the output field widths
		forall (pin of net) {
			lprt=maxint(lprt,strlen(pin.CPART.NAME));
			lpin=maxint(lpin,strlen(pin.NAME));
			}
		// Build the pin list header
		headl[headn]=" ";
		sprintf(headl[headn+1],REPPINH1,
		 lprt,ITMPRT,lpin,ITMPIN,lwid,ITMWIDTH+UNIT);
		sprintf(headl[headn+2],REPPINH2,
		 lprt,ITMULINE,lpin,ITMULINE,lwid,ITMULINE);
		headn+=3;
		}
	// Build the pin list display
	pn=0;
	forall (pin of net) {
		sprintf(pl[pn],REPPIN,lprt,pin.CPART.NAME,
		 lpin,pin.NAME,lwid,bae_numstring(baecvtl(pin.RWIDTH),4));
		pn++;
		}
	// Display the net data via popup
	sprintf(msg,UPRNETDATA,net.NAME);
	bae_setintpar(16,3063);
	if (popupmenu(0,msg,headl,headn,pl,pn,
	 "",0,1,1,headn+pn+2,0,0,"")==UINPOPABORT)
		error_abort();
	headn=4;
}

double treepathlen(
 int treenum,int trccnt=0,int viacnt=0,double minwidth=0.0,double maxwidth=0.0)
/*
// Get tree path length function
// Return value :
//	trace path length of given tree
// Parameters :
//	int netmode		: Net query mode
//	int treenum		: Path tree number
//	int trccnt=0		: Trace count
//	int viacnt=0		: Via count
//	double minwidth=0.0	: Min. trace width
//	double maxwidth=0.0	: Max. trace width
*/
{
	index L_FIGURE fig		/* Figure list index */;
	index L_UREF uref		/* Unnamed reference (via) index */;
	index L_LINE path		/* Path index */;
	index L_POINT p			/* Point index */;
	double trclen	= 0.0		/* Trace path length */;
	int pc				/* Path point count */;
	double x1,y1			/* Previous coordinates */;
	int t1				/* Previous point type */;
	double x2,y2			/* Pre-previous coordinates */;
	int t2				/* Pre-previous point type */;
	int sc		= 0		/* Segment count */;
	// Loop for all paths of selected tree
	forall (path where path.TREE==treenum) {
		// Update the trace length
		// Init the path point count
		pc=sc=0;
		// Loop for all path points
		forall (p of path) {
			// Increment the point counter
			pc++;
			// Get the segment length; update the trace length
			trclen+=
			 segmentlen(pc,p.TYP,p.X,p.Y,t1,x1,y1,t2,x2,y2,sc);
			}
		// Update path width extrema
		if (trccnt==0) {
			minwidth=maxwidth=path.WIDTH;
			}
		else {
			if (minwidth>path.WIDTH)
				minwidth=path.WIDTH;
			if (maxwidth<path.WIDTH)
				maxwidth=path.WIDTH;
			}
		// Increment the trace count
		trccnt++;
		}
	// Get the via count
	forall (uref where uref.TREE==treenum)
		viacnt++;
	// Also scan part level traces/vias
	curnetnum=treenum;
	forall (fig where fig.TYP==L_FIGNREF) {
		trcscnt=viascnt=0;
		trcslen=0.0;
		// Scan path level vias/traces
		if (lay_scanfelem(fig,0.0,0.0,0.0,0,0,
		 tlmacfunc,NULL,tlpathfunc,NULL,NULL,NULL,NULL))
			error_scan();
		// Update path width extrema
		if (trcscnt) {
			if (trccnt==0) {
				minwidth=trcminwidth;
				maxwidth=trcmaxwidth;
				}
			else{
				if (minwidth>trcminwidth)
					minwidth=trcminwidth;
				if (maxwidth<trcmaxwidth)
					maxwidth=trcmaxwidth;
				}
			trclen+=trcslen;
			}
		// Update counters
		trccnt+=trcscnt;
		viacnt+=viascnt;
		}
	// Return the trace path length
	return(trclen);
}

static int tlmacfunc(index L_MACRO macro,index L_POOL pool,
 int macinws,string refname,index L_LEVEL level)
/*
// Tree length scan macro scan function
// Return value :
//	(-1) on scan error, 0 on scan stop, 1 on scan continue
// Parameters :
//	index L_MACRO macro	: Macro index
//	index L_POOL pool	: Macro pool element
//	int macinws		: Macro in workspace flag
//	string refname		: Macro reference name
//	index L_LEVEL level	: Macro level
*/
{
	int viatree			/* Via tree number */;
	// Check class
	switch (macro.CLASS) {
		// Part
		case DDBCLLPRT :
		break;
		// Padstack
		case DDBCLLSTK :
		// Check if pin
		if (refname!="")
			break;
		// Get the via tree number from level
		if ((viatree=lay_getlevtreenum(level))<0)
			// Invalid level tree
			viatree=(-1);
		if (viatree==curnetnum)
			viascnt++;
		// Stop scan
		return(0);
		// Pad
		case DDBCLLPAD :
		// Stop scan
		return(0);
		}
	// Continue scan
	return(1);
}

static int tlpathfunc(
 index L_LINE path,int layer,int pathinws,index L_LEVEL level)
/*
// Tree length scan path function
// Return value :
//	zero if done or (-1) on error
// Parameters :
//	index L_LINE path	: Path index
//	int layer		: Path transformed layer code
//	int pathinws		: Path in workspace flag
//	index L_LEVEL level	: Path level
*/
{
	index L_POINT p			/* Point index */;
	int trctree			/* Trace tree number */;
	int pc				/* Path point count */;
	double x1,y1			/* Previous coordinates */;
	int t1				/* Previous point type */;
	double x2,y2			/* Pre-previous coordinates */;
	int t2				/* Pre-previous point type */;
	int sc		= 0		/* Segment count */;
	// Get the trace tree number from level
	if ((trctree=lay_getlevtreenum(level))<0)
		// Invalid level tree
		trctree=(-1);
	if (trctree==curnetnum) {
		// Update the trace length
		// Init the path point count
		pc=sc=0;
		// Loop for all path points
		forall (p of path) {
			// Increment the point counter
			pc++;
			// Get the segment length; update the trace length
			trcslen+=
			 segmentlen(pc,p.TYP,p.X,p.Y,t1,x1,y1,t2,x2,y2,sc);
			}
		// Update path width extrema
		if (trcscnt==0) {
			trcminwidth=trcmaxwidth=path.WIDTH;
			}
		else {
			if (trcminwidth>path.WIDTH)
				trcminwidth=path.WIDTH;
			if (trcmaxwidth<path.WIDTH)
				trcmaxwidth=path.WIDTH;
			}
		// Increment the trace count
		trcscnt++;
		}
	// Return without errors
	return(0);
}

void updpartrep()
/*
// Show parts with packages that do not match netlist
*/
{
	index L_NREF nref		/* Named reference index */;
	index L_CPART cpart		/* Connection part */;
	// Build the report header
	sprintf(headl[0],REPUPDPART);
	sprintf(headl[2],REPPACKHD1);
	sprintf(headl[3],REPPACKHD2);
	headl[1]="";
	headn=4;
	// Loop for all placed parts
	forall (nref) {
		// Check if part in netlist and of specified type
		if (lay_findconpart(nref.NAME,cpart)==0
		 && nref.MACRO.NAME!=cpart.PLNAME) {
			// Print the wrong package message
			sprintf(entryl[entryn],REPPACKAGE,
			 nref.NAME,cpart.PLNAME,nref.MACRO.NAME);
			entryn++;
			}
		}
	if (entryn==0) {
		bae_prtdialog(REPNOUPDPART);
		bae_clriactqueue();
		exit(0);
		}
	// Show report via popup
	bae_setintpar(16,3064);
	popupmenu(0,"",headl,headn,entryl,entryn,
	 "",0,1,-1,headn+entryn+2,100,0,"");
}

void netassistant()
/*
// Active net list assistant / perform actions
*/
{
	index L_CNET net		/* Net index */;
	index L_CPART part		/* Connection part index */;
	index L_CPIN pin		/* Connection pin index */;
	index L_FIGURE fig		/* Figure list index */;
	string msg			/* Message string */;
	double cy			/* Dialog box current y coordinate */;
	double dialwidth		/* Dialog box width */;
	double dialheight		/* Dialog box height */;
	double baseheight		/* Dialog box base height */;
	int boxidx			/* Dialog box index */;
	int actcode			/* Action code */;
	int reason			/* Callback reason */;
	int intval			/* Dialog box item integer value */;
	int oldcol			/* Old color index */;
	int selcol			/* Selected color */;
	int selpat			/* Selected pattern */;
	int orgcol			/* Original color */;
	int orgpat			/* Original pattern */;
	STRINGS vnamel			/* Visible net name list */;
	int vnamen = 0			/* Visible net name count */;
	STRINGS unamel			/* Unvisible net name list */;
	int unamen = 0			/* Unvisible net name count */;
	string name			/* Dialog box item name */;
	string varname			/* Variable name */;
	string partname			/* Part name */;
	int namidx			/* Net name item field index */;
	int pinidx			/* Net pin list item field index */;
	int infidx			/* Net info item field index */;
	int layidx			/* Layer display item field index */;
	int colidx			/* Net color item field index */;
	int fctidx			/* Net function item field index */;
	int focidx			/* Autofocus field index */;
	int layer = LAYERINV		/* Layer code */;
	int oldlaydefmode		/* Old layer default mode */;
	int hlmode			/* Net highlight mode */;
	int hlcolor			/* Net highlight color */;
	int newcolor			/* New net color */;
	int rangedis			/* Range check disabled flag */;
	int attdisp	= 0		/* Attribute entry display flag */;
	int autofocus	= 1		/* Autofocus flag */;
	int maxnetpin	= 0		/* Max. net pin count */;
	int pincnt			/* Current pin count */;
	int pidx			/* Current pin index */;
	int updflag	= 0		/* Update info display flag */;
	struct pctab {			// Pattern transfer table
		int p			/* Pattern code */;
		int h			/* Highlight pattern code */;
		};
	struct pctab phtab[] = {	// Palette to highlight pattern trans.
		{ 0x0010, 0x0010 }, { 0x0000, 0x0030 }, { 0x0020, 0x0090 },
		{ 0x0030, 0x0070 }, { 0x0130, 0x0270 }, { 0x0230, 0x0470 },
		{ 0x0330, 0x0670 }, { 0x0430, 0x0870 }, { 0x0530, 0x0A70 },
		{ 0x0630, 0x0C70 }, { 0x0730, 0x0E70 }, { 0x0830, 0x1070 },
		{ 0x0930, 0x1270 }, { 0x0A30, 0x1470 }, { 0x0B30, 0x1670 },
		{ 0x0C30, 0x1870 }, { 0x0D30, 0x1A70 }, { 0x0E30, 0x1C70 },
		{ 0x0F30, 0x1E70 }, { 0x1030, 0x2070 }, { 0x1130, 0x2270 },
		{ 0x1230, 0x2470 }, { 0x1330, 0x2670 }, { 0x1430, 0x2870 },
		{ 0x1530, 0x2A70 }, { 0x1630, 0x2C70 }, { 0x1730, 0x2E70 },
		{ 0x1830, 0x3070 }, { 0x1930, 0x3270 }, { 0x1A30, 0x3470 },
		{ 0x1B30, 0x3670 }, { 0x1C30, 0x3870 }, { 0x1D30, 0x3A70 },
		{ 0x1E30, 0x3C70 }, { 0x1F30, 0x3E70 } };
	int phtabn = arylength(phtab)	/* Palette/highl. trans. table len. */;
	char c				/* Character buffer */;
	int i				/* Loop control variable */;
	// Check if action call
	if (varget(VAR_PDBOXIDX,boxidx)==0 &&
	 varget(VAR_PDBOXACT,actcode)==0 && varget(VAR_PDBOXREAS,reason)==0 &&
	 varget(VAR_PDBOXIVAL,intval)==0 && varget(VAR_PDBOXNAME,name)==0) {
		// Remove callback parameters
		vardelete(VAR_PDBOXIDX);
		vardelete(VAR_PDBOXACT);
		vardelete(VAR_PDBOXREAS);
		vardelete(VAR_PDBOXIVAL);
		vardelete(VAR_PDBOXNAME);
		varget(GV_NAMEFIELD,namidx);
		varget(GV_PINFIELD,pinidx);
		varget(GV_INFOFIELD,infidx);
		varget(GV_PINCNT,pincnt);
		varget(GV_FUNCFIELD,fctidx);
		varget(GV_LAYFIELD,layidx);
		varget(GV_COLFIELD,colidx);
		varget(GV_FOCUSFIELD,focidx);
		varget(GV_LAYNUM,layer);
		bae_dialsetcurrent(boxidx);
		bae_dialgetdata(namidx,0,0.0,curnetname);
		strlower(curnetname);
		if (actcode==19) {
			if (reason==1)
				actcode=2;
			else
				bae_dialgetdata(fctidx,actcode,0.0,"");
			}
		else if (actcode==0) {
			bae_dialgetdata(fctidx,actcode,0.0,"");
			}
		bae_dialgetdata(colidx,newcolor,0.0,"");
		bae_dialgetdata(focidx,autofocus,0.0,"");
		bae_dialsetcurrent(0);
		if (autofocus && actcode!=1)
			bae_callmenu(9052);
		curseltyp=0;
		switch (actcode) {
			// Net info/pin display update
			case 2 :
			updflag=1;
			break;
			// Highlight toggle
			case 20 :
			if (curnetname=="$" && netattrsel())
				break;
			if (lay_findcontree(curnetname,net)!=0) {
				forall (net where netmatch(net)) {
					if (ged_gethighlnet(
					 net.NUMBER,hlmode,hlcolor)!=1)
						hlmode=hlcolor=0;
					hlmode= hlmode ? 0 : 1 ;
					ged_highlnet(
					 net.NUMBER,hlmode|(hlcolor<<1));
					}
				}
			else {
				if (ged_gethighlnet(
				 net.NUMBER,hlmode,hlcolor)!=1)
					hlmode=hlcolor=0;
				hlmode= hlmode ? 0 : 1 ;
				ged_highlnet(net.NUMBER,hlmode|(hlcolor<<1));
				}
			break;
			// Higlight focus toggle
			case 23 :
			ulsystem("#412:s3",0);
			break;
			// Net visibility status load
			case 24 :
			bae_storemenuiact(3,3,LMB);
			runulprog(UL_NETSTAT);
			break;
			// Net visibility status save
			case 25 :
			bae_storemenuiact(3,4,LMB);
			runulprog(UL_NETSTAT);
			break;
			// Net highlight/coloring load
			case 26 :
			bae_storemenuiact(3,0,LMB);
			runulprog(UL_NETSTAT);
			break;
			// Net highlight/coloring save
			case 27 :
			bae_storemenuiact(3,1,LMB);
			runulprog(UL_NETSTAT);
			break;
			// Higlight reset
			case 3 :
			ulsystem("#412:s2",0);
			break;
			// Zoom to net
			case 4 :
			if (lay_findcontree(curnetname,net)!=0)
				break;
			zoomtonet(net);
			break;
			// Zoom last
			case 5 :
			call(MNU_BAEZOOMALT);
			break;
			// Zoom all
			case 6 :
			call(MNU_BAEZOOMALL);
			break;
			// Add copper fill area
			case 7 :
			if (bae_getactmenu()>=0 || curnetname=="" ||
			 lay_findcontree(curnetname,net)!=0)
				break;
			if (layer!=LAYERINV)
				layerfadein(layer,COLFIN,1);
			mousegrab(1);
			oldlaydefmode=ged_getlaydefmode();
			bae_clriactqueue();
			bae_storetextiact(1,curnetname);
			if (layer!=LAYERINV && layer<POWLAYBASE) {
				ged_setlaydefmode(2);
				ged_setlayerdefault(layer);
				}
			bae_storecmdbuf(0,"#5014:'"+curnetname+"'",
			 bae_plainmenutext(UPRMADDCF)+" "+curnetname);
			call(5014);
			ged_setlaydefmode(oldlaydefmode);
			break;
			// Add active copper area
			case 8 :
			if (bae_getactmenu()>=0 || curnetname=="" ||
			 lay_findcontree(curnetname,net)!=0)
				break;
			if (layer!=LAYERINV)
				layerfadein(layer,COLFIN,1);
			mousegrab(1);
			oldlaydefmode=ged_getlaydefmode();
			bae_clriactqueue();
			bae_storetextiact(1,curnetname);
			if (layer!=LAYERINV && layer<POWLAYBASE) {
				ged_setlaydefmode(2);
				ged_setlayerdefault(layer);
				}
			bae_storecmdbuf(0,"#501:'"+curnetname+"'",
			 bae_plainmenutext(UPRMADDAC)+" "+curnetname);
			call(501);
			ged_setlaydefmode(oldlaydefmode);
			break;
			// Layer selection
			case 9 :
			if (bae_promptdialog(UPRSELLAY),ged_asklayer(layer,4))
				layer=LAYERINV;
			bae_dialsetcurrent(boxidx);
			bae_dialsetdata(layidx,PA_LAB,0,0.0,layer==LAYERINV ?
			 UPRNOLAYER : layername(layer));
			bae_dialsetcurrent(0);
			varset(GV_LAYNUM,layer);
			break;
			// Net info
			case 10 :
			if (lay_findcontree(curnetname,net)!=0)
				break;
			dispnetdata(net,1);
			break;
			// Color net(s)
			case 11 :
			if (curnetname=="$" && netattrsel())
				break;
			if (lay_findcontree(curnetname,net)!=0) {
				bae_setintpar(2,1);
				forall (net where netmatch(net)) {
					if (ged_gethighlnet(
					 net.NUMBER,hlmode,0)!=1)
						hlmode=0;
					ged_highlnet(
					 net.NUMBER,hlmode|(newcolor<<1));
					}
				bae_setintpar(2,0);
				screenredraw();
				}
			else {
				if (ged_gethighlnet(net.NUMBER,hlmode,0)!=1)
					hlmode=0;
				ged_highlnet(net.NUMBER,hlmode|(newcolor<<1));
				}
			break;
			// Airline visibility toggle
			case 12 :
			if (curnetname=="$" && netattrsel())
				break;
			if (lay_findcontree(curnetname,net)!=0) {
				forall (net where netmatch(net)) {
					if (net.VIS) {
						vnamel[vnamen]=net.NAME;
						vnamen++;
						}
					else {
						unamel[unamen]=net.NAME;
						unamen++;
						}
					}
				// Fade in unvisible nets
				if (unamen) {
					bae_clriactqueue();
					bae_storemenuiact(1,10,LMB);
					for (i=0;i<unamen;i++)
						bae_storetextiact(1,unamel[i]);
					// Terminate net name input list
					bae_storetextiact(1,UINPOPABORT);
					// Process net name inputs
					ulsystem("#806",0);
					}
				// Fade out visible nets
				if (vnamen) {
					bae_clriactqueue();
					bae_storemenuiact(1,11,LMB);
					for (i=0;i<vnamen;i++)
						bae_storetextiact(1,vnamel[i]);
					// Terminate net name input list
					bae_storetextiact(1,UINPOPABORT);
					// Process net name inputs
					ulsystem("#806",0);
					}
				}
			else {
				// Toggle net visibility
				bae_storemenuiact(1,net.VIS ? 11 : 10,LMB);
				bae_storetextiact(1,curnetname);
				// Terminate net name input list
				bae_storetextiact(1,UINPOPABORT);
				// Process net name inputs
				ulsystem("#806",0);
				}
			break;
			// Fade in all airlines
			case 13 :
			ulsystem("#806:s12",0);
			break;
			// Fade out all airlines
			case 14 :
			ulsystem("#806:s13",0);
			break;
			// Select net
			case 15 :
			if (curnetname=="$" && netattrsel())
				break;
			if (lay_findcontree(curnetname,net)!=0) {
				forall (net where netmatch(net))
					ged_groupselect(7,net.NUMBER,1);
				}
			else {
				ged_groupselect(7,net.NUMBER,1);
				}
			break;
			// Deselect net
			case 16 :
			if (curnetname=="$" && netattrsel())
				break;
			if (lay_findcontree(curnetname,net)!=0) {
				forall (net where netmatch(net))
					ged_groupselect(7,net.NUMBER,0);
				}
			else {
				ged_groupselect(7,net.NUMBER,0);
				}
			break;
			// Pick net
			case 17 :
			mousegrab(1);
			if (ged_asktreeidx(curnetname,net,4)!=(-1)) {
				bae_dialsetcurrent(boxidx);
				bae_dialsetdata(namidx,
				 PA_STR|PA_CHKNPAT|PA_HBRDREL,0,0.0,curnetname);
				bae_dialsetcurrent(0);
				updflag=1;
				}
			break;
			// Pick color
			case 18 :
			// Disable range check
			bae_getintpar(0,rangedis);
			bae_setintpar(0,1);
			// Set mouse cursor to window center
			bae_clriactqueue();
			bae_storemouseiact(1,0.5*(bae_wswinlx()+bae_wswinux()),
			 bae_wswinly()+0.8*(bae_wswinuy()-bae_wswinly()),
			 0x0C,LMB);
			bae_inpoint(0.0,0.0,0.0,0.0,0);
			// Restore old range check state
			bae_setintpar(0,rangedis);
			// Temporarily use layer 90 for color query
			oldcol=bae_getcolor(89);
			// Translate color pattern combination
			orgcol=newcolor&0x0F;
			orgpat=newcolor&~0x0F;
			if (orgpat==0x30)
				orgpat=0;
			else
				for (i=0;i<phtabn;i++)
					if (orgpat==phtab[i].h) {
						orgpat=phtab[i].p;
						break;
						}
			bae_setcolor(89,orgcol|(orgpat<<16));
			bae_clriactqueue();
			bae_storetextiact(1,"90");
			bae_storemouseiact(0,0.0,0.0,0,LMB);
			bae_storetextiact(1,"");
			bae_callmenu(108);
			selcol=bae_getcolor(89);
			// Restore layer 90 color
			bae_setcolor(89,oldcol);
			// Translate color pattern combination
			selpat=(selcol&~0x0FFFFF)>>16;
			selcol&=0x0F;
			if (selpat || selcol==0)
				for (i=0;i<phtabn;i++)
					if (selpat==phtab[i].p) {
						selpat=phtab[i].h;
						break;
						}
			// Use changed color/pattern item
			newcolor= orgcol==0 ? (selcol==0 ? selpat : selcol) :
			 (selpat==0 ? selcol : selpat);
			bae_dialsetcurrent(boxidx);
			bae_dialsetdata(colidx,PA_SB|PA_HBRDREL,
			 newcolor,0.0,"");
			bae_dialsetcurrent(0);
			break;
			// Zoom to net pin
			case 21 :
			bae_dialsetcurrent(boxidx);
			bae_dialgetdata(pinidx,0,0.0,partname);
			bae_dialsetcurrent(0);
			curpinname="";
			for (i=0;(c=partname[i])!='\0';i++)
				if (c==' ') {
					curpinname=strextract(partname,i+1,
					 strlen(partname));
					partname[i]='\0';
					break;
					}
			for (i=0;(c=curpinname[i])!='\0';i++)
				if (c==' ') {
					curpinname[i]='\0';
					break;
					}
			if (curpinname=="")
				break;
			if (lay_nrefsearch(partname,fig)!=0) {
				if (lay_findconpart(partname,part)==0) {
					mousegrab(1);
					// Part not found; place it
					bae_setintpar(35,0);
					bae_clriactqueue();
					bae_storetextiact(1,partname);
					bae_callmenu(MNU_GEDADDPART);
					bae_clriactqueue();
					bae_getintpar(35,updflag);
					updflag= updflag ? 0 : 1 ;
					if (autofocus)
						bae_callmenu(9052);
					}
				break;
				}
			lay_scanfelem(fig,0.0,0.0,0.0,0,0,
			 npinscan,NULL,NULL,NULL,NULL,NULL,NULL);
			break;
			// Resize
			case (-2) :
			// Abort
			case (-1) :
			default :
			vardelete(GV_NAMEFIELD);
			vardelete(GV_PINFIELD);
			vardelete(GV_INFOFIELD);
			vardelete(GV_PINCNT);
			vardelete(GV_FUNCFIELD);
			vardelete(GV_LAYFIELD);
			vardelete(GV_COLFIELD);
			vardelete(GV_FOCUSFIELD);
			vardelete(GV_LAYNUM);
			sprintf(varname,VAR_PDBOXSEQ,boxidx);
			vardelete(varname);
			sprintf(varname,VAR_PDBOXMODE,boxidx);
			vardelete(varname);
			bae_dialsetcurrent(boxidx);
			bae_dialclr();
			bae_dialsetcurrent(0);
			}
		// Check if net info update requested
		if (updflag) {
			pidx=0;
			bae_dialsetcurrent(boxidx);
			if (lay_findcontree(curnetname,net)==0) {
			    if (INFODISP) {
				sprintf(msg,UPRNNETDATA,net.NAME);
				bae_dialsetdata(infidx-1,PA_LAB,0,0.0,msg);
				dispnetdata(net,0);
				msg="";
				for (i=0;i<headn;i++) {
					if (headl[i][0]==' ')
						msg+=strextract(headl[i],3,
						 strlen(headl[i]))+"\n";
					else
						msg+=headl[i]+"\n";
					}
				bae_dialsetdata(infidx,PA_STR|PA_FNTFIX|
				 PA_NOEDIT|PA_HBRDREL,0,0.0,msg);
				}
			    else if (PINDISP) {
				sprintf(msg,UPRNNETPINS,net.NAME);
				bae_dialsetdata(pinidx-1,PA_LAB,0,0.0,msg);
				}
			    if (PINDISP) {
				maxnetpin=net.PINN;
				forall (pin of net) {
					if (pin.RWIDTH!=0.0)
						sprintf(msg,"%s %s %smm",
						 pin.CPART.NAME,pin.NAME,
						 bae_numstring(cvtlength(
						  pin.RWIDTH,0,2),4));
					else
						sprintf(msg,"%s %s",
						 pin.CPART.NAME,pin.NAME);
					if ((pin.CPART.USED&1)==0)
						msg+=REPUPLACED;
					pidx++;
					bae_dialsetdata(pinidx+pidx,PA_LBE,
					 0,0.0,msg);
					}
				}
			    }
			else {
			    if (INFODISP) {
				bae_dialsetdata(
				 infidx-1,PA_LAB,0,0.0,UPRUNETDATA);
				bae_dialsetdata(
				 infidx,PA_LAB,0,0.0,"");
				bae_dialsetdata(infidx,PA_STR|PA_FNTFIX|
				 PA_NOEDIT|PA_HBRDREL,0,0.0,"");
				}
			    else if (PINDISP) {
				bae_dialsetdata(
				 pinidx-1,PA_LAB,0,0.0,UPRNETPINS);
				}
			    maxnetpin=0;
			    }
			if (PINDISP) {
				for (;pidx<pincnt;pidx++)
					bae_dialsetdata(
					 pinidx+pidx+1,PA_NIL,0,0.0,"");
				bae_dialsetdata(pinidx,PA_LB|PA_HSCROLL|
				 PA_HBRDREL|PA_MULCOL|PA_MCALLBACK|
				 PA_SCALLBACK,(-1),0.0,"");
				}
			bae_dialsetcurrent(0);
			varset(GV_PINCNT,maxnetpin);
			}
		if (actcode!=(-2)) {
			bae_clriactqueue();
			exit(0);
			}
		}
	if (varget(GV_NAMEFIELD,namidx)==0)
		error(ERRDBLNETDB);
	// Check if dialog box support
	if (bae_dialclr())
		error(ERRNOWIN);
	baseheight=
	 DIAL_TOPMARG+4.0*DIAL_CTRVSTEP+5.0*DIAL_BUTVSTEP+5.0*DIAL_SEPVSTEP+0.2;
	if (INFODISP)
		baseheight+=DIAL_CTRVSTEP+DIAL_SEPVSTEP+INFOBOXH;
	if (PINDISP) {
		baseheight+=DIAL_SEPVSTEP+PINBOXH;
		if (!INFODISP)
			baseheight+=DIAL_CTRVSTEP;
		}
	dial_getboxsizemin(
	 bae_iniintval(PAR_MODALBOX,0) ? (PA_MODALBOX|3000) : 3000,
	 dialwidth,dialheight,DIAL_LEFTMARG+35.0,baseheight+NETBOXH,
	 DIAL_LEFTMARG+35.0+DIAL_RIGHTSMARG,baseheight+2.0);
	cy=DIAL_TOPMARG;
	bae_dialaddcontrol(PA_ACT,0,7,0,0.0,0.0,0.0,"",0,
	 DIAL_LEFTMARG,cy,BUTWIDTH,UPRADDCF);
	bae_dialaddcontrol(PA_ACT,0,8,0,0.0,0.0,0.0,"",0,
	 DIAL_LEFTMARG+BUTSPC,cy,BUTWIDTH,UPRADDAC);
	bae_dialaddcontrol(PA_ACT,0,15,0,0.0,0.0,0.0,"",0,
	 DIAL_LEFTMARG+2.0*BUTSPC,cy,BUTWIDTH,UPRSELECT);
	cy+=DIAL_CTRVSTEP;
	bae_dialaddcontrol(PA_ACT,0,9,0,0.0,0.0,0.0,"",0,
	 DIAL_LEFTMARG,cy,0.0,UPRLAYER);
	layidx=dial_label(6.0,cy,UPRNOLAYER);
	bae_dialaddcontrol(PA_ACT,0,16,0,0.0,0.0,0.0,"",0,
	 DIAL_LEFTMARG+2.0*BUTSPC,cy,BUTWIDTH,UPRDESELECT);
	cy+=DIAL_BUTVSTEP;
	bae_dialaddcontrol(PA_VSEP,0,0,0,0.0,0.0,0.0,"",0,
	 DIAL_LEFTMARG+1.5*BUTSPC+0.5*BUTWIDTH,DIAL_TOPMARG,cy-DIAL_TOPMARG,"");
	dial_hsep(cy);
	dial_label(0.0,cy,UPRHIGHLIGHT);
	bae_dialaddcontrol(PA_ACT,0,11,0,0.0,0.0,0.0,"",0,
	 DIAL_LEFTMARG+BUTSPC,cy,BUTWIDTH-2.0,UPRHLCOLOR);
	bae_dialaddcontrol(PA_ACT,0,18,0,0.0,0.0,0.0,"",0,
	 DIAL_LEFTMARG+BUTSPC+BUTWIDTH-1.5,cy,2.0,UPRCOLPICK);
	colidx=bae_dialadvcontrol(PA_SB|PA_HBRDREL,0,0,0,
	 0.0,0.0,0.0,"",0,DIAL_LEFTMARG+2.0*BUTSPC,cy,DIAL_RIGHTSMARG,16.0,"");
	dial_sbentry(0,0,UPRCOL0);
	dial_sbentry(0,1,UPRCOL1);
	dial_sbentry(0,2,UPRCOL2);
	dial_sbentry(0,3,UPRCOL3);
	dial_sbentry(0,4,UPRCOL4);
	dial_sbentry(0,5,UPRCOL5);
	dial_sbentry(0,6,UPRCOL6);
	dial_sbentry(0,7,UPRCOL7);
	dial_sbentry(0,8,UPRCOL8);
	dial_sbentry(0,9,UPRCOL9);
	dial_sbentry(0,10,UPRCOL10);
	dial_sbentry(0,11,UPRCOL11);
	dial_sbentry(0,12,UPRCOL12);
	dial_sbentry(0,13,UPRCOL13);
	dial_sbentry(0,14,UPRCOL14);
	dial_sbentry(0,15,UPRCOL15);
	dial_sbentry(0,0x10,UPRPOUTLINE);
	dial_sbentry(0,0x30,UPRPFILLED);
	dial_sbentry(0,0x90,UPRPDOTTED);
	for (i=0;i<32;i++) {
		sprintf(msg,UPRPATTERN,i+1);
		dial_sbentry(0,0x70|(i<<9),msg);
		}
	cy+=DIAL_CTRVSTEP;
	bae_dialaddcontrol(PA_ACT,0,20,0,0.0,0.0,0.0,"",0,
	 DIAL_LEFTMARG,cy,BUTWIDTH,UPRHLTOGGLE);
	bae_dialaddcontrol(PA_ACT,0,23,0,0.0,0.0,0.0,"",0,
	 DIAL_LEFTMARG+BUTSPC,cy,BUTWIDTH,UPRHLFOCUS);
	bae_dialaddcontrol(PA_ACT,0,3,0,0.0,0.0,0.0,"",0,
	 DIAL_LEFTMARG+2.0*BUTSPC,cy,BUTWIDTH-5.0,UPRHLRESET);
	bae_dialaddcontrol(PA_ACT,0,26,0,0.0,0.0,0.0,"",0,
	 DIAL_LEFTMARG+2.0*BUTSPC+BUTWIDTH-4.5,cy,2.0,UPRHLLOAD);
	bae_dialaddcontrol(PA_ACT,0,27,0,0.0,0.0,0.0,"",0,
	 DIAL_LEFTMARG+2.0*BUTSPC+BUTWIDTH-2.0,cy,2.0,UPRHLSAVE);
	cy+=DIAL_BUTVSTEP;
	dial_hsep(cy);
	bae_dialaddcontrol(PA_ACT,0,12,0,0.0,0.0,0.0,"",0,
	 DIAL_LEFTMARG,cy,BUTWIDTH,UPRMCTOGGLE);
	bae_dialaddcontrol(PA_ACT,0,13,0,0.0,0.0,0.0,"",0,
	 DIAL_LEFTMARG+BUTSPC,cy,BUTWIDTH,UPRMCON);
	bae_dialaddcontrol(PA_ACT,0,14,0,0.0,0.0,0.0,"",0,
	 DIAL_LEFTMARG+2.0*BUTSPC,cy,BUTWIDTH-5.0,UPRHLRESET);
	bae_dialaddcontrol(PA_ACT,0,24,0,0.0,0.0,0.0,"",0,
	 DIAL_LEFTMARG+2.0*BUTSPC+BUTWIDTH-4.5,cy,2.0,UPRHLLOAD);
	bae_dialaddcontrol(PA_ACT,0,25,0,0.0,0.0,0.0,"",0,
	 DIAL_LEFTMARG+2.0*BUTSPC+BUTWIDTH-2.0,cy,2.0,UPRHLSAVE);
	cy+=DIAL_BUTVSTEP;
	dial_hsep(cy);
	bae_dialaddcontrol(PA_ACT,0,4,0,0.0,0.0,0.0,"",0,
	 DIAL_LEFTMARG,cy,BUTWIDTH,UPRZOOMTO);
	bae_dialaddcontrol(PA_ACT,0,5,0,0.0,0.0,0.0,"",0,
	 DIAL_LEFTMARG+BUTSPC,cy,BUTWIDTH,UPRZOOMLAST);
	bae_dialaddcontrol(PA_ACT,0,6,0,0.0,0.0,0.0,"",0,
	 DIAL_LEFTMARG+2.0*BUTSPC,cy,BUTWIDTH,UPRZOOMALL);
	cy+=DIAL_BUTVSTEP;
	dial_hsep(cy);
	bae_dialaddcontrol(PA_ACT,0,0,0,0.0,0.0,0.0,"",0,
	 DIAL_LEFTMARG,cy,0.0,UPRNETDFUNC);
	fctidx=bae_dialaddcontrol(PA_SB|PA_HBRDREL,0,0,INFODISP ? 20 : 10,
	 0.0,0.0,0.0,"",0,DIAL_LEFTMARG+BUTSPC,cy,DIAL_RIGHTSMARG,"");
	dial_sbentry(0,10,bae_plainmenutext(UPRFCT2));
	dial_sbentry(0,20,UPRNHLTOGGLE);
	dial_sbentry(0,11,UPRHLCOLOR);
	dial_sbentry(0,12,UPRMCTOGGLE);
	dial_sbentry(0,4,UPRZOOMTO);
	dial_sbentry(0,7,UPRADDCF);
	dial_sbentry(0,8,UPRADDAC);
	dial_sbentry(0,15,UPRSELECT);
	dial_sbentry(0,16,UPRDESELECT);
	cy+=DIAL_CTRVSTEP;
	bae_dialaddcontrol(PA_ACT,0,17,0,0.0,0.0,0.0,"",0,
	 DIAL_LEFTMARG,cy,BUTWIDTH,UPRNETPICK);
	bae_dialaddcontrol(PA_ACT,0,10,0,0.0,0.0,0.0,"",0,
	 DIAL_LEFTMARG+BUTSPC,cy,BUTWIDTH,UPRNETINFO);
	focidx=bae_dialaddcontrol(PA_TOGGLE,0,0,autofocus,0.0,0.0,
	 0.0,"",0,DIAL_LEFTMARG+2.0*BUTSPC,cy,0.0,UPRAUTOFOCUS);
	cy+=DIAL_BUTVSTEP;
	// Store net name edit field
	namidx=dial_npatstring("",MAXKEYLEN,0.0,cy);
	// Store list box
	bae_dialadvcontrol(
	 PA_LB|PA_HBRDREL|(PINDISP ? (PA_MCALLBACK|PA_SCALLBACK) : 0),namidx,
	 19,(-1),0.0,0.0,0.0,"",0,DIAL_LEFTMARG,cy,DIAL_RIGHTSMARG,
	 dialheight-baseheight,"");
	// Store list box entries
	forall (net) {
		sprintf(curnetname,net.PINN==1 ? REPNETLISTS : REPNETLIST,
		 net.NAME,NETSEP,net.PINN);
		if (!attdisp && curnetname>UPRSELATTR) {
			bae_dialaddcontrol(PA_LBE,0,0,0,0.0,0.0,0.0,"",0,
			 0.0,0.0,0.0,UPRSELATTR);
			attdisp=1;
			}
		bae_dialaddcontrol(PA_LBE,0,0,0,0.0,0.0,0.0,"",0,
		 0.0,0.0,0.0,curnetname);
		if (maxnetpin<net.PINN)
			maxnetpin=net.PINN;
		}
	cy+=dialheight-baseheight;
	if (INFODISP) {
		cy+=DIAL_SEPVSTEP;
		bae_dialaddcontrol(PA_LAB|PA_HBRDREL,0,0,0,0.0,0.0,0.0,
		 "",0,DIAL_LEFTMARG,cy,DIAL_RIGHTSMARG,UPRUNETDATA);
		cy+=DIAL_CTRVSTEP;
		// Store list box
		infidx=bae_dialadvcontrol(PA_STR|PA_FNTFIX|PA_NOEDIT|PA_HBRDREL,
		 0,0,0,0.0,0.0,0.0,"",60000,DIAL_LEFTMARG,cy,DIAL_RIGHTSMARG,
		 INFOBOXH,"");
		cy+=INFOBOXH;
		}
	else {
		infidx=(-1);
		}
	if (PINDISP) {
		cy+=DIAL_SEPVSTEP;
		if (!INFODISP) {
			bae_dialaddcontrol(PA_LAB|PA_HBRDREL,0,0,0,0.0,0.0,0.0,
			 "",0,DIAL_LEFTMARG,cy,DIAL_RIGHTSMARG,UPRNETPINS);
			cy+=DIAL_CTRVSTEP;
			}
		// Store list box
		pinidx=bae_dialadvcontrol(PA_LB|PA_HSCROLL|PA_HBRDREL|
		  PA_MULCOL|PA_MCALLBACK,(-1),21,(-1),0.0,0.0,
		 0.0,"",0,DIAL_LEFTMARG,cy,DIAL_RIGHTSMARG,PINBOXH,"");
		for (i=0;i<maxnetpin;i++)
			bae_dialaddcontrol(PA_NIL,0,0,0,0.0,0.0,0.0,"",0,
			 0.0,0.0,0.0,"");
		cy+=PINBOXH;
		}
	else {
		pinidx=(-1);
		}
	cy+=DIAL_SEPVSTEP+0.2;
	bae_setintpar(16,
	 bae_iniintval(PAR_MODALBOX,0) ? (PA_MODALBOX|3000) : 3000);
	// Display dialog box
	if ((boxidx=bae_dialboxperm("!"+UPRNETFUNC,0,dialwidth,cy))<0)
		error_abort();
	sprintf(varname,VAR_PDBOXSEQ,boxidx);
	varset(varname,"conutil:s6");
	sprintf(varname,VAR_PDBOXMODE,boxidx);
	varset(varname,PDBOXLOADDIS|PDBOXPLCUPD);
	varset(GV_NAMEFIELD,namidx);
	varset(GV_PINFIELD,pinidx);
	varset(GV_INFOFIELD,infidx);
	varset(GV_PINCNT,pincnt);
	varset(GV_FUNCFIELD,fctidx);
	varset(GV_LAYFIELD,layidx);
	varset(GV_COLFIELD,colidx);
	varset(GV_FOCUSFIELD,focidx);
	varset(GV_LAYNUM,layer);
}

int netattrsel()
/*
// Select global net attribute match criteria
// Return value :
//	0 if done or (-1) on abort
*/
{
	index L_FIGURE fig		/* Figure list index */;
	index L_CNET net		/* Connection net index */;
	index L_CPART part		/* Connection part index */;
	index L_CPIN pin		/* Connection pin index */;
	index L_ATTRIBUTE attr		/* Attribute index */;
	int an	= 0			/* Attribute count */;
	// Select attribute type
	bae_promptdialog(UPRATYP);
	switch (bae_askmenu(9,UPRATYP1,UPRATYP2,UPRATYP3,UPRATYP4,UPRATYP5,
	 UPRATYP6,UPRATYP7,UPRATYP8,UPRABORT)) {
		// Net attribute match
		case 0 :
		curseltyp=1;
		curnetname="";
		bae_nameclr();
		forall (net) {
			forall (attr of net)
				bae_nameadd(attr.NAME,"","","",2);
			if (net.RDIST!=0.0)
				bae_nameadd(REPNDIST,"","","",2);
			forall (pin of net where pin.RWIDTH!=0.0) {
				bae_nameadd(REPNRWIDTH,"","","",2);
				break;
				}
			}
		bae_nameadd(REPNPRIO,"","","",2);
		bae_nameadd(REPNNUMBER,"","","",2);
		bae_setintpar(16,3118);
		if (bae_askname(curattrname,UPRSELANAM,MAXKEYLEN))
			return(-1);
		bae_nameclr();
		switch (curattrname) {
			case REPNPRIO :
			forall (net)
				bae_nameadd(itoa(net.PRIOR),"","","",2);
			break;
			case REPNNUMBER :
			forall (net)
				bae_nameadd(itoa(net.NUMBER),"","","",2);
			break;
			case REPNDIST :
			forall (net where net.RDIST!=0.0)
				bae_nameadd(bae_numstring(
				 cvtlength(net.RDIST,0,2),5),"","","",2);
			break;
			case REPNRWIDTH :
			forall (net)
			    forall (pin of net where pin.RWIDTH!=0.0)
				bae_nameadd(bae_numstring(
				 cvtlength(pin.RWIDTH,0,2),5),"","","",2);
			break;
			default :
			forall (net)
			    forall (attr of net where attr.NAME==curattrname) {
				bae_nameadd(attr.VALUE,"","","",2);
				break;
				}
			}
		entryn=0;
		while (bae_nameget(entryn,entryl[entryn],"","","",0)==0)
			entryn++;
		// Build the attribute selection popup menu
		sprintf(headl[0],REPATTVALL,curattrname);
		headl[1]="";
		headn=2;
		bae_setintpar(16,3110);
		if ((curattrval=popupmenu(4,UPRSELAVAL,headl,headn,entryl,
		 entryn,UINPOPABORT,0,-1,-1,0,0,0,UINPOPABORT))=="" ||
		 curattrval==UINPOPABORT)
			return(-1);
		break;
		// Part attribute match
		case 1 :
		curseltyp=2;
		curnetname="";
		bae_nameclr();
		forall (part)
			forall (attr of part) {
				bae_nameadd(attr.NAME,"","","",2);
				an++;
				}
		if (an==0) {
			bae_msgbox(0,WRNNOPARTATT,"");
			return(-1);
			}
		bae_setintpar(16,3118);
		if (bae_askname(curattrname,UPRSELANAM,MAXKEYLEN))
			return(-1);
		bae_nameclr();
		forall (part)
			forall (attr of part where attr.NAME==curattrname) {
				bae_nameadd(attr.VALUE,"","","",2);
				break;
				}
		entryn=0;
		while (bae_nameget(entryn,entryl[entryn],"","","",0)==0)
			entryn++;
		// Build the attribute selection popup menu
		sprintf(headl[0],REPATTVALL,curattrname);
		headl[1]="";
		headn=2;
		bae_setintpar(16,3110);
		if ((curattrval=popupmenu(4,UPRSELAVAL,headl,headn,entryl,
		 entryn,UINPOPABORT,0,-1,-1,0,0,0,UINPOPABORT))=="" ||
		 curattrval==UINPOPABORT)
			return(-1);
		break;
		// Pin attribute match
		case 2 :
		curseltyp=3;
		curnetname="";
		bae_nameclr();
		forall (pin)
			forall (attr of pin) {
				bae_nameadd(attr.NAME,"","","",2);
				an++;
				}
		if (an==0) {
			bae_msgbox(0,WRNNOPINATT,"");
			return(-1);
			}
		bae_setintpar(16,3118);
		if (bae_askname(curattrname,UPRSELANAM,MAXKEYLEN))
			return(-1);
		bae_nameclr();
		forall (pin)
			forall (attr of pin where attr.NAME==curattrname) {
				bae_nameadd(attr.VALUE,"","","",2);
				break;
				}
		entryn=0;
		while (bae_nameget(entryn,entryl[entryn],"","","",0)==0)
			entryn++;
		// Build the attribute selection popup menu
		sprintf(headl[0],REPATTVALL,curattrname);
		headl[1]="";
		headn=2;
		bae_setintpar(16,3110);
		if ((curattrval=popupmenu(4,UPRSELAVAL,headl,headn,entryl,
		 entryn,UINPOPABORT,0,-1,-1,0,0,0,UINPOPABORT))=="" ||
		 curattrval==UINPOPABORT)
			return(-1);
		break;
		// Part nets
		case 3 :
		bae_prtdialog(UPRSELPART);
		if (ged_pickelem(fig,L_FIGNREF))
			return(-1);
		// Check if netlist part
		if (lay_findconpart(fig.NAME,part))
			return(-1);
		// Store part name
		curattrname=fig.NAME;
		curseltyp=7;
		break;
		// Pin count
		case 4 :
		curseltyp=4;
		if (askint(curnetpn,UPRPINCNT,10))
			return(-1);
		break;
		// Minimum pin count
		case 5 :
		curseltyp=5;
		if (askint(curnetpn,UPRMINPINCNT,10))
			return(-1);
		break;
		// Maximum pin count
		case 6 :
		curseltyp=6;
		if (askint(curnetpn,UPRMAXPINCNT,10))
			return(-1);
		break;
		// Name (pattern) match
		case 7 :
		default :
		curseltyp=0;
		}
	// Attribute type selection done
	return(0);
}

int netmatch(index L_CNET cnet)
/*
// Check if given net matches current selection criteria
// Return value :
//	one on criteria match else zero
// Parameter :
//	index L_CNET cnet		: Net connection index
*/
{
	index L_CPART part		/* Connection part index */;
	index L_CPIN pin		/* Connection pin index */;
	index L_ATTRIBUTE attr		/* Attribute index */;
	switch (curseltyp) {
		// Net attribute match
		case 1 :
		switch (curattrname) {
			case REPNPRIO :
			if (curattrval==itoa(cnet.PRIOR))
				return(1);
			break;
			case REPNNUMBER :
			if (curattrval==itoa(cnet.NUMBER))
				return(1);
			break;
			case REPNDIST :
			if (curattrval==
			 bae_numstring(cvtlength(cnet.RDIST,0,2),5))
				return(1);
			break;
			case REPNRWIDTH :
			forall (pin of cnet)
				if (curattrval==
				 bae_numstring(cvtlength(pin.RWIDTH,0,2),5))
					return(1);
			break;
			default :
			forall (attr of cnet where attr.NAME==curattrname)
				if (strmatch(attr.VALUE,curattrval) ||
				 attr.VALUE==curattrval)
					return(1);
				else
					break;
			}
		break;
		// Part attribute match
		case 2 :
		forall (pin of cnet) {
			part=pin.CPART;
			forall (attr of part where attr.NAME==curattrname)
				if (strmatch(attr.VALUE,curattrval) ||
				 attr.VALUE==curattrval)
					return(1);
				else
					break;
			}
		break;
		// Pin attribute match
		case 3 :
		forall (pin of cnet)
			forall (attr of pin where attr.NAME==curattrname)
				if (strmatch(attr.VALUE,curattrval) ||
				 attr.VALUE==curattrval)
					return(1);
				else
					break;
		break;
		// Pin count match
		case 4 :
		return(cnet.PINN==curnetpn ? 1 : 0);
		// Minimum pin count
		case 5 :
		return(cnet.PINN>=curnetpn ? 1 : 0);
		// Maximum pin count
		case 6 :
		return(cnet.PINN<=curnetpn ? 1 : 0);
		// Part match
		case 7 :
		forall (pin of cnet)
			if (pin.CPART.NAME==curattrname)
				return(1);
		break;
		// Name (pattern) match
		case 0 :
		default :
		return(strmatch(cnet.NAME,curnetname));
		}
	// No match
	return(0);
}


// User interaction routines

int asknetcontinue(string netname,int highlflag,string answer)
/*
// Prompt for continue
// Return value :
//	zero if ok, (-1) on abort request
// Parameters :
//	string netname		: Net name
//	int highlflag		: Highlight flag
//	string answer		: Answer string
*/
{
	// Prompt for continue
	bae_setmousetext("");
	answer=bae_readtext(
	 REPNET+netname+(highlflag ? UPRCONTY : UPRCONTX),MAXKEYLEN);
	strlower(answer);
	// Check for abort command
	if (answer==UINPOPABORT || answer==UINSTOP) {
		answer="";
		// User abort request
		return(-1);
		}
	else if (highlflag) {
		switch (answer) {
			case UINHIGHL :
			answer="";
			// User abort with highlight request
			return(1);
			case UINPREV :
			answer="";
			// Skip to previous net
			return(2);
			case UINFIX :
			answer="";
			// Fix the net traces
			return(3);
			case UINUNFIX :
			answer="";
			// Unfix the net traces
			return(4);
			case UINDELETE :
			answer="";
			// Delete the net traces
			return(5);
			case UINSIZE :
			answer="";
			// Set trace width
			return(6);
			case UINFUNC :
			answer="";
			// Select net manipulation function
			bae_promptdialog(UPRFCT);
			switch (bae_askmenu(8,UPRNFCT1,UPRNFCT2,UPRNFCT3,
			 UPRNFCT4,UPRNFCT5,UPRNFCT6,UPRNFCT7,UPRABORT)) {
				// Abort
				case 0 :
				return(-1);
				// Abort with highlight
				case 1 :
				return(1);
				// Fix traces
				case 2 :
				return(3);
				// Unfix traces
				case 3 :
				return(4);
				// Delete traces
				case 4 :
				return(5);
				// Set trace width
				case 5 :
				return(6);
				// Skip to previous net
				case 6 :
				return(2);
				default :
				return(-1);
				}
			}
		}
	return(0);
}

int gcname(string name)
/*
// Get or create a name list entry
// Return value :
//	entry index
// Parameters :
//	string name		: Name
*/
{
	int slb		= 0		/* Search lower boundary */;
	int sub		= entryn-1	/* Search upper boundary */;
	int sidx			/* Search index */;
	int compres			/* Compare result */;
	// Loop until search area empty
	while (slb<=sub) {
		// Get the search index
		sidx=(slb+sub)>>1;
		// Get the comparison result
		if ((compres=strcmp(name,entryl[sidx]))==0)
			// Name found
			return(sidx);
		// Update the search area
		if (compres<0)
			sub=sidx-1;
		else
			slb=sidx+1;
		}
	// Update the name list
	for (sidx=entryn;sidx>slb;sidx--)
		entryl[sidx]=entryl[sidx-1];
	// Insert name
	entryl[slb]=name;
	entryn++;
	// Return sheet index
	return(slb);
}

double atof_len(string val)
/* Convert a string to length value with unit evaluation */
/*
//	string val			: Value string
*/
{
	string convbuf			/* Conversion buffer */;
	double mulfac			/* Multiplication factor */;
	int sidx			/* Source string index */;
	int didx			/* Destination string index */;
	char c				/* Scan character */;
	char c1, c2, c3, c4		/* Last scan character */;
	// Init. the scan variables
	sidx=didx=0;
	// Skip leading blanks/tabs
	while (val[sidx]!='\0' && (val[sidx]==' ' || val[sidx]=='\t'))
		sidx++;
	// Copy the number chars.
	while ((c=val[sidx])!='\0') {
		// Convert colons to dots
		if (c==',')
			c='.';
		// Store the char. to the conv. buffer
		convbuf[didx++]=c;
		// Update the source char. index
		sidx++;
		}
	// Terminate the conversion buffer string
	convbuf[didx]='\0';
	// Skip trailing blanks/tabs
	while (didx>0 && ((c=val[didx-1])==' ' || c=='\t'))
		didx--;
	// Get last (unit) characters
	c4= didx>=4 ? tolower(val[didx-4]) : '\0' ;
	c3= didx>=3 ? tolower(val[didx-3]) : '\0' ;
	c2= didx>=2 ? tolower(val[didx-2]) : '\0' ;
	c1= didx>=1 ? tolower(val[didx-1]) : '\0' ;
	// Get the units conversion factor
	if ((c4=='i' && c3=='n' && c2=='c' && c1=='h') ||
	 c1=='"' || c1=='\'')
		mulfac=25.4;
	 else if (c3=='m' && c2=='i' && c1=='l')
		mulfac=0.0254;
	 else if ((c2=='u' || c2=='\350' || c2=='\265') && c1=='m')
		mulfac=0.001;
	 else
		mulfac=1.0;
	// Return the converted value
	return(cvtlength(mulfac*atof(convbuf),2,0));
}

// User Language program end